;c13noehsqc.fa
;3D (1H,13C,1H) NOESY-HSQC with optional 15N, 13C' and 2H decoupling
;This version makes use of the gp gradient syntax.
;Muhandiram et. al, J. Magn. Reson. B 102, 317-321 (1993)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: c13noehsqc.fa,v 1.8 2002/01/08 22:51:25 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C, f4: 2H (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm
;o3p: 43ppm
;o4p:: 4.5ppm
;
;d1: relaxation delay=d1+0.1s
;p1 90 H at pl1
;p3 90 C at pl3
;p25 90 2H pulse at pl15 (optional)
;d8 mixing time
;pl10: 10kHz H1 field for purge pulses
;pl0 120dB
;
;N15 Waltz-16 PCPD at pl12, cpdprg2 (optional)
;C13 GARP decoupling using CPDPRG3 and PCPD at pl13
;C'  Compensated SEDUCE1 decoupling of C', using p31 at sp3, 
;    shape seduce1c5/6, offset 0, cpdprg4 waltz16sp3p31 (optional).
;H2  Waltz-16 (cpdprg5) decoupling, using p90 (PCPD) at pl15
;C evolution:
;  in0, SW(C)=1/(2*in0), typically 24 ppm
;  l4 complex points
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion.
;  cnst0=1 gives (270,-540) phase distortion (use LP to correct).
;  Processing: extend the FID backwards cnst0 points
;  and apply (90,-180) phase correction.
;H1 evolution:
;  in10, SW(H)=1/(2*in10), typically 8 ppm
;  set cnst10 to 0 (preferably) or 1 to make d10 the smallest possible
;  positive delay. cnst10=0 gives (90,-180) phase distortion in F1.
;  cnst10=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  Processing: extend the FID backwards cnst10 points 
;  and apply (90,-180) phase correction. An additional -45 dgr phase 
;  correction is needed.
;  l6 complex points
;
;ns=16,32,..., ds=16,32,...
;
;Recommendations for gradients:
;gpz1:  22%
;gpz2:  22%
;gpz3:  29%
;gpz4:  24%
;gpz5:  44%
;gpz6: -26%
;gpx7:  27% (adjust for magic-angle)
;gpz7:  15%
;gpnam1: sine.50
;gpnam2: sine.100
;gpnam3: sine.100
;gpnam4: sine.50
;gpnam5: sine.100
;gpnam6: sine.100
;gpnam7: sine.50
;
;#define ONE_D		; uncomment for 1D experiment
#define H1_EVOL 	; comment out for 2D w/o H1 evolution
#define C13_EVOL	; comment out for 2D w/o C13 evolution
#define N15_DEC		; uncomment for N15 decoupling
#define SEDUCE		; uncomment for compensated SEDUCE-1 decouling of C'
;#define H2_DEC		; uncomment to enable H2 decoupling
#define MESSERLE	; this may improve solvent suppression
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
#define D f5
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef C13_EVOL
#undef H1_EVOL
#endif
;
define pulse H1_90
define pulse H1_180
define pulse C13_90
define pulse C13_180
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define delay TAUA4
define delay TAUA7
define delay CEN_HC1
;
"H1_90=p1"
"H1_180=H1_90*2"
"C13_90=p3"
"C13_180=C13_90*2"
"d11=100m"                      ;disk i/o
"d12=10u"                       ;power switching etc.
"d13=5u"                        ;a short delay
"d14=60u"			;ip,id etc.
"d16=300u"			;gradient recovery
"p10=8m"
"p11=5m"
"d7=C13_90*2+d13"

"GRAD1=400u"
"GRAD2=3m"
"GRAD3=1.0m"
"GRAD4=400u"
"GRAD5=4m"
"GRAD6=3m"
"GRAD7=400u"

"d2=1.7m"               ;1/4J
"TAUA4=d2-GRAD4-d13"
"TAUA7=d2-GRAD7-d13"
"CEN_HC1=C13_90-H1_90"
"d18=d8-GRAD2-GRAD3-C13_90-d16*2-d13"

#ifdef H1_EVOL
  "d10=((cnst10*2+1)*in10-H1_90*1.273-C13_90*4-d13*2)/2"
#endif

#ifdef EXPTCORR
  "d31=2*(TAUA4+TAUA7+GRAD4+GRAD7)+GRAD1+GRAD2+GRAD3+GRAD5+GRAD6"
#endif

#ifdef C13_EVOL

#ifdef SEDUCE
"d0=((cnst0*2+1)*in0-C13_90*1.273-H1_180-d13*4-d12*2)/2"
#define SED_ON d13 \n d12 pl0:C \n d13 cpds4:C
#define SED_OFF d13 do:C \n d12 pl3:C \n d13
#else
"d0=((cnst0*2+1)*in0-C13_90*1.273-H1_180-d13*2)/2"
#define SED_ON d13
#define SED_OFF d13
#endif

#endif

#ifdef H2_DEC
#define H2_DEC_ON d12 pl15:D \n p25:D ph1 \n d13 cpds5:D
#define H2_DEC_OFF d13 do:D \n p25:D ph3
#else
#define H2_DEC_ON d13
#define H2_DEC_OFF d13
#endif


#include <Avance.incl>
#include <Grad.incl>

1 ze
  d11 LOCKDEC_ON
2 d13 do:C
  d14 H2_LOCK
  d11 LOCKH_OFF
3 d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d12 pl10:H
  (p10 ph0 d13 p11 ph1):H
  d13
  d1 pl1:H pl3:C
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  d13 H2_PULSE
  (C13_90 ph0):C
  d13
  GRAD1:gp1		;400u, 15G/cm
  d16
#ifdef N15_DEC
  d12 pl12:N
  d13 cpds2:N
#endif
; Begin Proton evolution
#ifdef H1_EVOL
  (H1_90 ph13):H
  d10
  (C13_90 ph0 d13 C13_180 ph1 d13 C13_90 ph0):C
  d10
#else
  (H1_90 ph23):H
  d13
#endif
  (H1_90 ph0):H
; End Proton evolution
#ifdef N15_DEC
  d13 do:N
#endif
; Begin mixing time
  d18
  GRAD2:gp2		;3ms, 15G/cm
  d16
  (C13_90 ph0):C
  d13
  GRAD3:gp3		;1ms, 20G/cm
  d16
; End mixing time
  (H1_90 ph0):H
  d13
  GRAD4:gp4		;400u, 16G/cm
  TAUA4
  (CEN_HC1 H1_180 ph0):H (C13_180 ph0):C
  d13
  GRAD4:gp4		;400u, 16G/cm
  TAUA4
#ifdef MESSERLE
  (H1_90*55 ph0):H
  d13
#endif
  (H1_90 ph1):H
  d13
  GRAD5:gp5		;4m, 30G/cm
  d16
  H2_DEC_ON
; Begin Carbon evolution
  (C13_90 ph14):C
#ifdef C13_EVOL
  SED_ON
  d0 
  (H1_180 ph0):H
  d0
  SED_OFF
#else
  d13
#endif 
  (C13_90 ph0):C
; End Carbon evolution
  H2_DEC_OFF
  d13
  GRAD6:gp6		;3m, -18G/cm
  d16
  (H1_90 ph15):H 
  d13
  d7
  GRAD7:gp7		;400u, 20G/cm
  TAUA7                                                      
  (CEN_HC1 H1_180 ph0):H (C13_180 ph0):C
  d13
  GRAD7:gp7		;400u, 20G/cm
  TAUA7 BLKGRAMP
  (C13_90 ph0 d13 C13_90 ph16):C
  (d13 d12 pl13):C (H1_90 ph15):H
  go=2 ph31 cpds3:C

#ifdef ONE_D
  d11 do:C wr #0 H2_LOCK
#else
  d11 do:C wr #0 if #0 zd H2_LOCK
#endif
  d13 LOCKH_OFF
#ifdef C13_EVOL
  d14 ip14
  lo to 3 times 2
  d14 id0
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd0
#endif
#ifdef H1_EVOL
  d14 ip13
  d14 ip13
  lo to 5 times 2
  d14 id10
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif
  d14 LOCKDEC_OFF

exit
  
ph0=0
ph1=1
ph2=2
ph3=3
ph13=(8) 1 1 5 5
ph23=0 0 2 2
ph14=0 2
ph15={0}*4 {1}*4 {2}*4 {3}*4
ph16=0 0 2 2
ph31=0 2 2 0 3 1 1 3 2 0 0 2 1 3 3 1