;ccnoesy4d.fa
;4D (13C,13C)-HMQC-NOESY-HSQC -  with PFG 
;Vuister et al., J. Magn. Reson. B101, 210-213 (1993)
;Morshauser and Zuiderweg, J. Magn. Reson. 139, 232-239 (1999)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu) 
;
;  $Id: ccnoesy4d.fa,v 1.4 2001/08/04 19:13:08 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your 
;  information. Support for the use of this pulse program is only 
;  provided to users of the National Magnetic Resonance Facility 
;  at Madison (NMRFAM). Users of this pulse program employ it at 
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison 
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f3: 13C (channel assignments may be changed below)
;o1p: 4.7 ppm
;o3p: 31 ppm
;
;d1: relaxation delay=d1+0.1s, e.g. d1=0.6s
;p1 90 H at pl1
;p3 90 C at pl3 (p3>p1)
;d8 mixing time
;
;C13 GARP decoupling using CPDPRG3 and PCPD at pl13
;Chemical Chift evolution:  H(t3)-C(t2)-NOE-C(t1)-H(t4)
;H1 evolution (t3, origination proton):
;  in10, SW(H)=1/(2*in10), e.g. 1.5 ppm (2.9 ppm)
;  l4 complex points, e.g. 16 (16).
;  The initial delay is dw/2 for (90,-180) phase correction.
;  An additional 45 dgr phase correction is required (ph0) in processing.
;  H1 chemical shift axis is reversed: set reverse to true in XWIN-NMR.
;C evolution (t2, origination carbon):
;  in0, SW(C2)=1/(2*in0), e.g. 29 ppm (32 ppm)
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F3.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  Processing: extend the FID backwards cnst0 points
;  and apply (90,-180) phase correction
;  l6 complex points, e.g. 48 (36)
;C evolution (t1, destination carbon):
;  in20, SW(C1)=1/(2*in20), e.g. 29 ppm (32 ppm)
;  set cnst20 to 0 (preferably) or 1 to make d20 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F1.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  Processing: extend the FID backwards cnst20 points
;  and apply (90,-180) phase correction
;  l8 complex points, e.g. 72 (72)
;td2 = 2*l4, td1=4*l6*l8
;
;ns=2,4,..., ds=2,4,...
;
;Recommendations for gradients:
;gpz1:  10%
;gpx2:  18% adjust for magic angle
;gpz2:  10%
;gpz3:  10%
;gpz4:  10%
;gpz5:  12%
;gpz6:  15%
;gpz7:  22%
;gpx8:  18% adjust for magic angle
;gpz8:  10%
;gpnam1: sine.100
;gpnam2: sine.50
;gpnam3: sine.100
;gpnam4: sine.100
;gpnam5: sine.50
;gpnam6: sine.100
;gpnam7: sine.100
;gpnam8: sine.50
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
#define C_EVOL1		; comment out for 2D/3D w/o C13 t1 evolution
#define C_EVOL2		; comment out for 2D/3D w/o C13 t2 evolution
#define H_EVOL 		; comment out for 2D w/o H1 evolution
#define EXPTCORR	; uncomment to have "expt" report the correct exp. time

;Define channel assignments:
#define H f1
#define C f3
;
;You shouldn't have to worry about anything beyond this point :-)
;
;
;sanity checks
;
#ifdef ONE_D
#undef C_EVOL1
#undef C_EVOL2
#undef H_EVOL
#endif
;
define delay TAUA
define delay TAUA5
define delay TAUA8
define delay TAUB
define delay TAUB2
define delay TAUB2A
define delay TAUM
define delay TAUM34
define delay CEN_HC1
define pulse H1_90
define pulse H1_180
define pulse C13_90
define pulse C13_180
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD8
;
"d11=100m"			;disk i/o
;"d12=10u"			;power switching etc.
"d13=5u"			;just a short delay
"d14=60u"			;ip,id etc
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"C13_90=p3"
"C13_180=C13_90*2"
;
"GRAD1=1.0m"
"GRAD2=500u"
"GRAD3=2.0m"
"GRAD4=4.0m"
"GRAD5=500u"
"GRAD6=1.0m"
"GRAD7=1.2m"
"GRAD8=500u"

"TAUA=1.7m"			; 1/4J
"TAUB=2*TAUA"			; 1/2J
"TAUM=d8"
"TAUM34=TAUM-GRAD3-GRAD4-C13_90-d16*2-d13"
"TAUA5=TAUA-GRAD5-d13"
"TAUA8=TAUA-GRAD8-d16-d13"
"TAUB2=TAUB-GRAD2-d13"
"TAUB2A=TAUB2-C13_90*4-d13*4"
"CEN_HC1=C13_90-H1_90"

#ifdef H_EVOL
 "d10=d13+in10/2"
#else
 "d10=d13"
#endif
#ifdef C_EVOL2
 "d0=((cnst0*2+1)*in0-(C13_90*1.273+H1_180))/2"
#else
 "d0=d13"
#endif
#ifdef C_EVOL1
 "d20=((cnst20*2+1)*in20-(C13_90*1.273+H1_180))/2"
#else
 "d20=d13"
#endif

#ifdef EXPTCORR
  "d31=2*(GRAD2+TAUA5+GRAD5+GRAD8+TAUA8)+GRAD1+TAUB2+TAUB2A+TAUM34+GRAD3+GRAD4+GRAD6+GRAD7"
#endif


#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d14 do:C
  d11 LOCKH_OFF
  d14
3 d14
  d14
  d14
4 d14
  d14
5 d14
  d14
  d14
6 d14
  d14
7 d14
  d14
  d14
8 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d1 pl1:H pl3:C
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  (C13_90 ph0):C
  d13
  GRAD1:gp1		; 1.0m, 7G/cm, z, sine.100
  d16
; Begin HMQC transfer, 1H->13C
#ifdef H_EVOL
  (H1_90 ph11):H
#else
  (H1_90 ph0):H
#endif
  d13
  GRAD2:gp2		; 500u, 15G/cm, ma, sine.50
  TAUB2
; Begin t2 Carbon evolution
  (C13_90 ph12):C
  d0 
  (H1_180 ph0):H
  d0 
  (C13_90 ph0):C
; End t2 Carbon evolution
  d13
  GRAD2:gp2		; 500u, 15G/cm, ma, sine.50
  TAUB2A
; Begin Proton evolution
  d10
  (C13_90 ph1 d13 C13_180 ph0 d13 C13_90 ph1):C
  d10
  (H1_90 ph0):H
; End Proton evolution
; Begin mixing time
  TAUM34
  GRAD3:gp3		; 2.0m, 7G/cm, z, sine.100
  d16
  (C13_90 ph0):C
  d13
  GRAD4:gp4		; 4.0m, 7G/cm, z, sine.100
  d16
; End mixing time
; Begin INEPT transfer, 1H->13C
  (H1_90 ph0):H
  d13
  GRAD5:gp5*-1		; 500u, -8G/cm, z, sine.50
  TAUA5
  (CEN_HC1 H1_180 ph0):H (C13_180 ph0):C
  d13
  GRAD5:gp5*-1		; 500u, -8G/cm, z, sine.50
  TAUA5
  (H1_90*55 ph0):H
  d13
  (H1_90 ph1):H
; End INEPT transfer, 1H->13C
  d13
  GRAD6:gp6*-1		; 1.0m, -10G/cm, z, sine.100
  d16
; Begin t1 Carbon evolution
  (C13_90 ph13):C
  d20 
  (H1_180 ph0):H
  d20 
  (C13_90 ph0):C
; End t1 Carbon evolution
  d13
  GRAD7:gp7		; 1.2m, 15G/cm, z, sine.100
  d16
  (H1_90 ph0):H
  d13
  GRAD8:gp8		; 500u, 15G/cm, ma, sine.50
  TAUA8
  d16
  (CEN_HC1 H1_180 ph0):H (C13_180 ph0):C 
  d13
  TAUA8 pl13:C 
  GRAD8:gp8		; 500u, 15G/cm, ma, sine.50
  d16 BLKGRAMP 
  (H1_90 ph2):H

  go=2 ph31 cpd3:C

#ifdef ONE_D
  d11 do:C wr #0
#else
  d11 do:C wr #0 if #0 zd
#endif
  d13 LOCKH_OFF
#ifdef H_EVOL
  d14 ip11
  d14 ip11
  lo to 3 times 2
  d14 id10
  d14 ip31
  d14 ip31
  lo to 4 times l4   ;no of complex points in t2
  d14 rd10
#endif
#ifdef C_EVOL2
  d14 ip12 
  lo to 5 times 2
  d14 id0 
  d14 ip31
  d14 ip31
  lo to 6 times l6   ;no of complex points in t1
  d14 rd0 
#endif
#ifdef C_EVOL1
  d14 ip13
  lo to 7 times 2
  d14 id20 
  d14 ip31
  d14 ip31
  lo to 8 times l8   ;no of complex points in t3
#endif

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph11=(8) 1
ph12=0 2
ph13=0 
ph31=0 2