;cdcancocaha.fa
; 3D CDCA(NCO)CAHA: (HDCD/HACA)->N->CO->CA->HA transfer experiment
; sequential assignment of prolines and poly-proline stretches in
; 13C/15N-labeled proteins
; Bottomley et al., J. Biomol. NMR (1999) 13, 381-385.
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: cdcancocaha.fa,v 1.1 2002/02/02 01:27:32 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm,
;o3p:  56ppm,
;
;d1: relaxation delay = d1+0.1s
;p1 90 dgr. H at pl1
;p2 90 dgr. N at pl2
;p3 90 dgr. Ca at pl3 for 90 dgr. semi-selective: field strength=dNu/sqrt(15),
;   dNu=(175ppm-56ppm)*bf3. p3 53.0 us at 600 MHz.
;p4 90 dgr. Ca at pl4 for 180 dgr. semi-selective: field strength=dNu/sqrt(3),
;   dNu=(175ppm-56ppm)*bf3. p4 23.7 us at 600 MHz.
;p5 180 dgr. CO rectangular shaped (spnam5) at power sp5, offset CO-Ca,
;   semi-selective: field strength=dNu/sqrt(3),	dNu=(176ppm-55ppm)*bf3.
;   p5 47.4 us at 600 MHz.
;p6 180 dgr. shaped Ca refocusing REBURP (spnam6 reburp.256) pulse.
;   p6 = (1000/y) ms, where y is the spectrometer frequency in MHz
;   (1.6ms at 600, 1.3ms at 750).
;p7 90 dgr. CO square shaped (spnam7) at power sp7, offset CO-Ca.
;   Semi-selective: field strength=dNu/sqrt(15),
;   dNu=(175ppm-56ppm)*bf3. p7 53.0 us at 600 MHz.
;pl0 120dB
;
;H1  Waltz-16 or DIPSI-2 (cpdprg1), 90 dgr. pulse (PCPD) at pl11
;N15 Waltz-16 (cpdprg2), using p90 (PCPD2) at pl12
;C13 alpha Waltz-16 (cpdprg3) decoupling, 90 dgr. pulse (PCPD) at pl13
;C13 alpha evolution:
;  in10=in30=1/(2*SW(CA)), ND10=2
;  l4 complex points; max is d10/in10 (~3.5ms/in10). "2 td" =2*l4
;  Process as echo-antiecho
;C13 alpha/delta evolution:
;  in0=in20=1/(2*SW(CAD)), ND0=2
;  l6 complex points; max is d20/in20 (~7ms/in20). "1 td" = 2*l6
;  Process as States.
;ns=16, 32, ..., ds=16, 32,...
;
;Recommendations for triple-axis (single-axis) gradients:
;gpx1:  35% (0%)
;gpy1:  35% (0%)
;gpz1:   0% (40%)
;gpx2:  50% (0%)
;gpz2:   0% (50%)
;gpy3:  50% (0%)
;gpz3:   0% (50%)
;gpx4:  30% (0%)
;gpz4:   0% (30%)
;gpz5:  44% (44%)
;gpx6:  50% (0%)
;gpz6:   0% (50%)
;gpz7:  44% (44%)
;gpy9:  50% (0%)
;gpz9:   0% (50%)
;gpnam1: sine.100
;gpnam2: sine.100
;gpnam3: sine.100
;gpnam4: sine.50
;gpnam5: sine.100
;gpnam6: sine.50
;gpnam7: sine.20
;gpnam9: sine.50
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
#define CAD_EVOL	; comment out for 2D w/o C13 alpha/delta evolution
#define CA_EVOL		; comment out for 2D w/o C13 alpha evolution
;#define MESSERLE	; this may improve solvent suppression
#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD5)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef CAD_EVOL
#undef CA_EVOL
#endif
;
;
define delay TAU
define delay TAU1
define delay TAU6
define delay TAU9
define delay DELTA
define delay DELTA1
define delay DELTA2
define delay DELTA5
define delay CT
define delay TN
define delay TN1
define delay TN2
define delay ETA
define delay ZETA
define delay CEN_HC1
define pulse H1_90
define pulse H1_180
define pulse N15_90
define pulse N15_180
define pulse CA_90
define pulse CA_180
define pulse COA_90
define pulse COA_180
define pulse CA_REBP
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD9

"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;just a short delay
"d14=60u"			;ip,id etc
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"N15_90=p2"
"N15_180=N15_90*2"
"CA_90=p3"
"CA_180=p4*2"
"COA_180=p5"
"CA_REBP=p6"
"COA_90=p7"
"d6=H1_90"
"d7=CA_90"
;
"GRAD1=3m"
"GRAD2=1.5m"
"GRAD3=1.4m"
"GRAD4=500u"
#ifndef OPTIM_P19
"p19=1586u"
#endif
"GRAD5=p19"
"GRAD6=500u"
"GRAD7=200u"
"GRAD9=500u"

"CT=7.0m"	;Called T in paper
"DELTA=3.4m"
"DELTA1=2.0m"
"DELTA2=5.4m"
"TN=14.0m"	;Called tauN in paper
"TN1=TN-CA_180-d13-d12"
"TN2=TN-CA_180-d13*2-d12"
"ETA=4.5m"
"ZETA=3.52m"	;Called delta in paper
"TAU=1.7m"	;Called Delta/2 in paper
"TAU1=1.5m"
"DELTA5=DELTA-GRAD5-d16-d13"
"TAU6=TAU-GRAD6-d16"
"TAU9=TAU-GRAD9-d16"
"CEN_HC1=(CA_180-H1_180)/2"
;
"d0=d13"
"d20=CT+d0-COA_180-d12-d13"
"d10=ZETA-COA_180-d12*2-d13*3"
"d30=ZETA-COA_180-DELTA5-GRAD5-d16-d12-d13*4"


#ifdef EXPTCORR
   "d31=2*(TAU1+TN+TAU6+GRAD6+TAU9+GRAD9+GRAD7)+GRAD1+GRAD2+CT+TN1+GRAD3+TN2+GRAD4+DELTA5+GRAD5"
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d13 do:C
  d14 LOCKH_OFF
  d11
  3m
  d14
3 d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif  
  d1 pl1:H pl2:N
  d13 LOCKH_ON
  d13 UNBLKGRAMP
; Purge 15N
  (N15_90 ph0):N
  d13
  GRAD1:gp1			; 3 ms, 25G/cm, x,y
  d16*2
; INEPT transfer from H to Ca,d
  (H1_90 ph0):H
  TAU1 pl4:C
  (CEN_HC1 H1_180 ph0):H (CA_180 ph12):C
  TAU1
#ifdef MESSERLE
  (H1_90*55 ph0):H
  d13
#endif
  (H1_90 ph1):H
  d13
  GRAD2:gp2			; 1.5 ms, 35G/cm, z
  d16 pl3:C
; INEPT transfer from Ca,d to N
  (CA_90 ph12):C
  (CT) (DELTA1 pl11 d13 cpds1 ph0):H (d0 d12 pl0 COA_180:sp5 ph0 d13 d12 pl0):C
  (d0 CA_REBP:sp6 ph13):C
  (d20) (d13 N15_180 ph0):N (d13 d12 pl0):C
  (COA_180:sp5 ph0 d13 d12 pl3):C
  (CA_90 ph0):C
  d13 do:H
; INEPT transfer from N to C'
  (N15_90 ph14):N
  (TN1 pl4):C (DELTA2 pl11 d13 cpds1 ph0):H
  (CA_180 ph0 d13 d12 pl0):C
  (N15_180 ph0):N
  (TN) (d13 COA_180:sp5 ph0):C
  (N15_90 ph0):N
  d13 do:H
  d13
  GRAD3:gp3			; 1.4 ms, 35G/cm, z
  d16 pl0:C
; INEPT from CO to N, refocus Ca,d
  (COA_90:sp7 ph15):C
  (TN) (d13 ETA pl4 CA_180 ph0 d13 d12 pl0):C
  (COA_180:sp5 ph0):C
  d13
  (TN2 pl4):C (N15_180 ph0):N
  (CA_180 ph0 d13 d12 pl0):C
  (COA_90:sp7 ph0):C
  d13
  GRAD4:gp4			; 500 us, 25 G/cm, x
  d16 pl3:C pl11:H
  d13 cpds1:H ph0
; Begin constant time evolution on Ca
  (CA_90 ph0):C
  (d13 d12 pl0 COA_180:sp5 ph0):C
  (d13 d12 pl0):C (d13 cpds2):N
  d10
  d13 do:N
  (CA_REBP:sp6 ph17):C
  (d13 d12 pl0 COA_180:sp5 ph0):C
  d13
  (d30 cpds2):N
  d13 do:H
  DELTA5 pl3:C
  d13 do:N
  GRAD5:gp5*EA			; 1.591 ms, +/- 25 G/cm, z
  d16 pl1:H
  (CA_90 ph16):C
; End constant time
; Sensitivity enhanced coherence transfer from Ca to H
  d6
  (H1_90 ph0):H
  TAU6
  GRAD6:gp6			; 500 us, 25 G/cm, x
  d16 pl4:C
  (CA_180 ph0):C
  (H1_180 ph0):H
  d16
  GRAD6:gp6			; 500 us, 25 G/cm, x
  TAU6 pl3:C
  d7
  (CA_90 ph1):C
  (H1_90 ph1):H
  TAU9
  GRAD9:gp9			; 500 us, 25 G/cm, y
  d16 pl4:C
  (CEN_HC1 H1_180 ph0):H (CA_180 ph0):C
  d16
  GRAD9:gp9			; 500 us, 25 G/cm, y
  TAU9
  (H1_90 ph0):H
  d13
  GRAD7:gp7			; 200 us, 25 G/cm, z
  d16
  (H1_180 ph0):H
  d13
  GRAD7:gp7*-1			; 200 us, -25 G/cm, z
  d16 pl13:C
  d13 BLKGRAMP
  go=2 ph31 cpd3:C

#ifdef ONE_D
  d11 do:C wr #0
#else
  d11 do:C wr #0 if #0 zd
#endif
  d13 LOCKH_OFF
#ifdef CA_EVOL
  3m igrad EA
  d14 ip16
  d14 ip16
  lo to 3 times 2
  d14 dd10
  d14 id30
  lo to 4 times l4
  d14 rd10
  d14 rd30
#else
  d14*6
  3m
#endif
#ifdef CAD_EVOL
  d14 ip12
  lo to 5 times 2
  d14 id0
  d14 dd20 
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph12=0
ph13={0}*4 {1}*4 {2}*4 {3}*4
ph14=0 2
ph15=0 0 2 2
ph16=0
ph17={0}*4 {2}*4 {1}*4 {3}*4
ph31=0 2 2 0 2 0 0 2  2 0 0 2 0 2 2 0