;cnnoesy4d.fa
;4D (13C,15N)-HMQC-NOESY-HSQC-SE - Gradient enhanced
;Muhandiram, Xu, Kay: J. Biomol. NMR 3, 463-70 (1993)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: cnnoesy4d.fa,v 1.1 1999/08/07 05:10:15 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C (channel assignments may be changed below)
;Gradient program: facnnoesy4d
;o1p: use fq1list facnnoesy4d.H (4.0ppm,8.10ppm) if F1SWITCH defined below,
;     (may not work with DQD) otherwise: o1p 4.7ppm
;o2p 118ppm, 
;o3p 43ppm
;
;p1 90 H at pl1
;p2 90 N at pl2
;p3 90 C at pl3
;d8 mixing time
;pl10: power for 1H purge pulses at 8.5kHz field at 500 MHz
;N15 Waltz-16 PCPD at pl12, using cpdprg2
;use cpdprg3 waltz16sp3 for compensated SEDUCE1 C' decoupling
;  using PCPD at sp3
;H1 evolution:
;  in10, SW(H)=1/(2*in10), typically 8ppm
;  l6 complex points
;  A 45 dgr phase correction is required (ph0).
;  H1 chemical shift axis is reversed: set reverse to true.
;N15 evolution:
;  in20, SW(N)=1/2*in20
;  l4 complex points
;  Process as Echo/Anti-Echo
;C evolution:
;  in0, SW(C)=1/(2*in0), typically 24ppm
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F1.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  Processing: extend the FID backwards cnst0 points
;  and apply (90,-180) phase correction
;  l8 complex points
;ns=2, 4, ...; ds=2*m*ns, m=1,2,...
;td2 = 2*l6, td1=4*l4*l8
;Recommendations for gradients:
;p15=1.0m
;p16=500u
;p17=3.0m
;p18=1.25m
;p19=125u
;cnst21=12% (8G/cm)
;cnst22=12% (8G/cm)
;cnst23=7% (5G/cm)
;cnst24=-22% (-15G/cm)
;cnst25=30% (30G/cm combined x and z)
;cnst26=7% (5G/cm)
;cnst27/28=-/+30% (-/+30G/cm)
;cnst30=1.800 (adjust) for magic angle gradient (Gx/Gz) or 0 for Gz only.

;#define ONE_D		;uncomment for 1D experiment; set cnst28=cnst27=-30G/cm
#define N_EVOL		;comment out for 2D or 3D w/o N15 evolution; if not used, set cnst28=cnst27=-30G/cm
#define H_EVOL		;comment out for 2D or 3D w/o H1 evolution
#define C_EVOL		;comment out for 2D or 3D w/o C13 evolution
;#define F1SWITCH	;uncomment for H1 carrier jump, between 4.0 ppm and 8.1 ppm
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
;
;You shouldn't have to worry about anything beyond this point :-)
;
;
;sanity checks
;
#ifdef ONE_D
#undef N_EVOL
#undef H_EVOL
#undef C_EVOL
#endif
;
"p10=8.0m"
"p11=5.0m"
"p21=p1*2"
"p22=p2*2"
"p23=p3*2"
"d2=3.3m"                       ;tau-a
"d3=2.25m"                      ;tau-b
"d4=1.5m"                       ;tau-c
"d5=500u"                       ;tau-d
"d11=100m"                      ;disk i/o
"d12=10u"                       ;power switching etc.
"d13=5u"
"d14=40u"                       ;ip,id etc.
"d16=300u"                      ;gradient recovery
"d10=3u"
"d20=3u"
"d6=p1"
"d7=p2"
"d21=p3*2+d10*2"
"d22=d2-p16"
"d23=d3-p16"
"d24=d4-p18+d20*2+p1*2+d13*2+d12"
"d25=d5-p19"
"d28=d8-p19-d16-p2"
"d29=p2-p1"

#ifdef C_EVOL
 "d0=((cnst0*2+1)*in0-(p3*1.273+d12*2+d13*4))/2"
#endif

#define SED_ON d13 \n d12 pl0:C \n d13 cpds3:C

#define SED_OFF d13 do:C \n d12 pl3:C \n d13

#include <Avance.incl>
#include <Gradfa.incl>

1 ze
2 d11 do:N
  d14
  d14
3 d14
  d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d14
  d14
7 d14
  d14
  d14
8 20u LOCKH_OFF
#ifdef F1SWITCH
  50u fq1:H
#endif
  d12 pl10:H 
  (p10 ph0):H
  3u 
  (p11 ph1):H
  3u
  d1 pl1:H pl2:N pl3:C
  20u LOCKH_ON
  (p3 ph0):C
  d13
  GRADIENT15(cnst21)
  d16
#ifdef H_EVOL
  (p1 ph5):H
#else
  (p1 ph0):H
#endif
  GRADIENT16(cnst21)
  d22
  d21
  (p3 ph6):C
#ifdef C_EVOL
  SED_ON
  d0 
  (p21 ph0):H
  d0 
  SED_OFF
#else
  3u
  (p21 ph0):H
  3u
#endif
  (p3 ph0):C
  GRADIENT16(cnst21)
  d22
  d10
  (p23 ph0):C
  d10
  (p1 ph0):H
; Mixing time
  d13
#ifdef F1SWITCH
  d28 fq1:H
#else
  d28
#endif
  (p2 ph0):N
  d13
  GRADIENT17(cnst23)
  d16 pl1:H
; End mixing time
; INEPT to N
  (p1 ph0):H
  d13
  GRADIENT16(cnst22)
  d23
  (d29 p21 ph0):H (p22 ph0):N
  d13
  GRADIENT16(cnst22)
  d23 
  (p1*55 ph0):H
  d13
  (p1 ph1):H
  d13
  GRADIENT15(cnst24)
  d16
  SED_ON
; N evolution
  (p2 ph7):N
  d20 
  (p21 ph0):H
  d20 
  d4
  SED_OFF
  (p22 ph0):N
  GRADIENT18(cnst25)
  d24
; Double-INEPT back to H
  (p2 ph8):N
  d6
  (p1 ph0):H
  d13
  GRADIENT16(cnst22)
  d23
  (p22 ph0):N
  (p21 ph0):H
  d13
  GRADIENT16(cnst22)
  d23 
  d7
  (p2 ph1):N
  (p1 ph1):H 
  d13
  GRADIENT16(cnst26)
  d23                                                       
  (d29 p21 ph0):H (p22 ph0):N
  d13
  GRADIENT16(cnst26)
  d23 
  (p1 ph0):H
  d5
  (p21 ph0):H
  d13
  GRADIENT19(cnst27)
  d25 pl12:N
  go=2 ph31 cpd2:N
#ifdef ONE_D
  d11 do:N wr #0
#else
  d11 do:N wr #0 if #0 zd
#endif
#ifdef N_EVOL
  d14 ip8
  d14 ip8
  lo to 3 times 2
  d14 id20
  d14 ip7
  d14 ip7
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd20
#endif
#ifdef H_EVOL
  d14 ip5
  d14 ip5
  lo to 5 times 2
  d14 id10 
  d14 ip31
  d14 ip31
  lo to 6 times l6
  d14 rd10 
#endif
#ifdef C_EVOL
  d14 ip6
  lo to 7 times 2
  d14 id0 
  d14 ip31
  d14 ip31
  lo to 8 times l8
#endif
  20u LOCKH_OFF
exit

ph0=0
ph1=1
ph2=2
ph3=3
ph5=(8) 1
ph6=0 2
ph7=0 
ph8=0
ph31=0 2