;hcacose.fa
;3D CT-HCACO-SE - Gradient enhanced, constant time.
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hcacose.fa,v 1.2 2000/11/14 04:24:10 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm
;o3p: use fq3list fahcacose.C (55,175,55ppm)
;
;d1: relaxation delay = d1+0.1s
;p1 90 H at pl1
;p3 90 Ca at pl3 
;   semi-selective: p90=sqrt(15)/(4*dNu), dNu=(175ppm-56ppm)*bf3); 64us at 500MHz
;p4 90 CO at pl4
;   semi-selective: p90=sqrt(15)/(4*dNu), dNu=(175ppm-56ppm)*bf3); 64us at 500MHz
;p5 180 Ca square shaped (spnam5) at power sp5, offset Ca-CO (-120ppm)
;   semi-selective: p180=sqrt(15)/(2*dNu), dNu=(175ppm-56ppm)*bf3); 128us at 500MHz
;p8 180 CO square shaped (spnam8) at power sp8, offset CO-Ca (120ppm)
;   semi-selective: p180=sqrt(15)/(2*dNu), dNu=(175ppm-56ppm)*bf3); 128us at 500MHz
;pl0 120dB
;cnst11 1 for backbone HC or 2 for optimum sensitivity for Gly
; and side chain amides.
;
;H1  Waltz-16x or DIPSI-2x (cpdprg1), using p90 (PCPD) at pl10
;N15 Waltz-16 (cpdprg2), 90 dgr pulse (PCPD) at pl12
;C13 GARP or Waltz-16 (cpdprg3) using p90 (PCPD) at pl13
;Ca evolution:
;  in10=in30, SW(N)=1/(2*in10), typ. 35-40 ppm
;  l4 complex points; max. is (d10/in10)+1
;  Process as echo-antiecho.
;  Ca chemical shift axis has reverse orientation
;CO evolution:
;  in0, SW(C)=1/(2*in0), typ. 15 ppm
;  l6 complex points
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F1.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  C' chemical shift axis is OK
;ns=8, 16, ..., ds=8, 16, ...
;
;Recommendations for gradients:
;gpz1:  12%
;gpz2:  29%
;gpz3:  29%
;gpz4: -18%
;gpx5:  54% adjust for magic angle
;gpz5:  30%
;gpz6:  12%
;gpz7:   9%
;gpx8:  54% adjust for magic angle
;gpz8:  30%
;gpnam1: sine.50
;gpnam2: sine.100
;gpnam3: sine.20
;gpnam4: sine.100
;gpnam5: sine.100
;gpnam6: sine.50
;gpnam7: sine.50
;gpnam8: sine.20
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
; To make this a 1D experiment uncomment the following line:
;#define ONE_D		;uncomment for 1D version exp, set cnst28=cnst27
#define CA_EVOL		;uncomment for 3D and H1-CA 2D exp
#define CO_EVOL		;uncomment for 3D and H1-CO 2D exp, set cnst28=cnst27
#define MESSERLE	;improves solvent suppression
#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD8)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef CA_EVOL
#undef CO_EVOL
#endif
;
aqseq 321
;
define delay TAUA
define delay TAUB
define delay TAUB1
define delay TAUB2
define delay TAUC
define delay TAUC3
define delay TAUD
define delay TAUD5
define delay TAUE
define delay TAUF
define delay TCC
define delay DELTA
define delay INV_4J
define delay CEN_HC1
define pulse H1_90
define pulse H1_180
define pulse CA_90
define pulse CA_180
define pulse CAO_180
define pulse CO_90
define pulse CO_180
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD8

"d11=100m"
"d12=10u"
"d13=5u"
"d14=60u"
"d16=300u"				;Gradient recovery delay
"H1_90=p1"
"H1_180=H1_90*2"
"CA_90=p3"
"CA_180=CA_90*2"
"CAO_180=p5"
"CO_90=p4"
"CO_180=p8"
;
"GRAD1=500u"
"GRAD2=1.0m"
"GRAD3=250u"
"GRAD4=1.0m"
"GRAD5=1200u"
"GRAD6=400u"
"GRAD7=400u"
#ifndef OPTIM_P19
"p19=302u"			; configurable: set to the optimum value on your instrument
#endif
"GRAD8=p19"

"INV_4J=1.8m"
"TAUA=INV_4J*0.9-GRAD1-d13"
"TAUB=3.1m"
"TAUB1=TAUB-CO_180-GRAD3-d12-d13"
"TAUC=INV_4J/cnst11"
"TAUB2=TAUB-TAUC-CO_180-H1_180-d12-d13"
"TAUC3=TAUC-GRAD3-d13"
"TCC=3.8m"
"d10=TCC"
"TAUD=2*TAUC"
"d30=TCC-TAUD-CO_180-d12*2-d13"
"TAUD5=TAUD-GRAD5-d16-d13"
"TAUE=(INV_4J/cnst11)*0.9-GRAD6-d13"
"TAUF=INV_4J*0.9-GRAD7-d13"
"DELTA=GRAD8+d16+d13*2"
"CEN_HC1=CA_90-H1_90"
"d6=H1_90"
"d7=CA_90"

#ifdef CO_EVOL
 "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-d12*2-d13*2)/2"
#endif

#ifdef EXPTCORR
  "d31=2*(TAUA+TAUE+TAUF+GRAD1+GRAD6+GRAD7)+TAUB1+TAUB2+TAUC3+TAUD5+GRAD2+GRAD3+GRAD4+GRAD5+GRAD8+DELTA"
#endif

#define N_DEC_ON d13 \n d12 pl12:N \n d13 cpds2:N

#define N_DEC_OFF d13 do:N

#define H1_DEC_ON d13 \n d12 pl10:H \n d13 cpds1:H

#define H1_DEC_OFF d13 do:H \n d12 pl1:H


#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d13 do:C
  d11 LOCKH_OFF
  3m
  d14
  d14
3 d14
  d14
  d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d1 pl1:H pl12:N
  d14 fq3:C
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  (H1_90 ph0):H
  d13
  GRAD1:gp1			; 500us, 8G/cm, sine.50
  TAUA pl3:C
  (CEN_HC1 H1_180 ph0):H (CA_180 ph0):C
  d13
  GRAD1:gp1			; 500us, 8G/cm, sine.50
  TAUA
#ifdef MESSERLE
  (H1_90*55 ph0):H
  d13
#endif
  (H1_90 ph11):H
  d13
  GRAD2:gp2		; 1.0ms, 20G/cm, sine.100
  d16
  (CA_90 ph0):C
  d12 pl0:C
  (CO_180:sp8 ph0):C
  d13
  GRAD3:gp3		; 250us, 20G/cm, sine.20
  TAUB1 pl3:C
  (CA_180 ph0):C
  d12 pl0:C
  (CO_180:sp8 ph0):C
  d13
  TAUB2 pl3:C
  (H1_180 ph0):H
  d13
  GRAD3:gp3		; 250us, 20G/cm, sine.20
  TAUC3
  (CA_90 ph0):C
  d13
  GRAD4:gp4		; 1ms, -18G/cm, sine.100
  d16 fq3:C
  N_DEC_ON
  H1_DEC_ON
  d12 pl4:C
  (CO_90 ph13):C
  d13
#ifdef CO_EVOL
  d0
  d12 pl0:C
  (CAO_180:sp5 ph0):C
  d0
#endif
  d13
  d12 pl4:C
  (CO_90 ph0):C
  d13
  50u fq3:C
  d12 pl3:C
  (CA_90 ph14):C
  d10
  (CA_180 ph15):C
  d12 pl0:C
  (CO_180:sp8 ph0):C
  d30
  H1_DEC_OFF
  TAUD5
  N_DEC_OFF
  GRAD5:gp5*EA*-1		; 720us, -/+40G/cm, ma, sine.100
  d16 pl3:C
  (CA_90 ph16):C
  d6
  (H1_90 ph0):H
  d13
  GRAD6:gp6		; 400us, 8G/cm, sine.50
  TAUE
  (CA_180 ph0):C
  (H1_180 ph0):H 
  d13
  GRAD6:gp6		; 400us, 8G/cm, sine.50
  TAUE
  d7
  (CA_90 ph1):C
  (H1_90 ph1):H 
  d13
  GRAD7:gp7		; 400us, 6G/cm, sine.50
  TAUF
  (CEN_HC1 H1_180 ph0):H (CA_180 ph0):C
  d13
  GRAD7:gp7		; 400us, 6G/cm, sine.50
  TAUF
  (H1_90 ph0):H
  DELTA pl13:C
  (H1_180 ph0):H
  d13
  GRAD8:gp8		; 180u, 40G/cm, ma, sine.20
  d13
  d16 BLKGRAMP

  go=2 ph31 cpds3:C

#ifdef ONE_D
  d11 do:C wr #0
#else
  d11 do:C wr #0 if #0 zd
#endif
  d13 LOCKH_OFF
#ifdef CA_EVOL
  3m igrad EA
  d14 ip16
  d14 ip16
  lo to 3 times 2
  d14 dd10
  d14 id30
  d14 ip14
  d14 ip14
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd10
  d14 rd30
#else
  d14*10
  3m
#endif
#ifdef CO_EVOL
  d14 ip13
  lo to 5 times 2
  d14 id0
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif

exit
  
ph0=0
ph1=1
ph2=2
ph3=3
ph11=1
ph13=0 2
ph14=0
ph15=0 0 1 1 2 2 3 3
ph16=0
ph31=0 2 2 0