;hcchcosy.fa
;3D HCCH COSY with PFG
;Based on Kay et al., J. Magn. Reson. B 101, 333-337 (1993)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hcchcosy.fa,v 1.2 2000/07/06 16:25:52 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C (channel assignments may be changed below)
;o1p: 4.7 ppm
;o2p: 118 ppm
;o3p:  43 ppm
;
;p1 90 H1  at pl1
;p2 90 N15 at pl2
;p3 90 C13 at pl3
;p5 180 CO SEDUCE1 shape at power sp5, offset CO-43 ppm
;p10 1 ms 1H purge pulse at pl10
;13C Waltz-16 or GARP PCPD at pl13 (cpdprg3)
;H1 evolution:
;   SW(H)=1/(2*in0)
;   l4 complex points
;C13 evolution:
;  in10, SW(C)=1/(2*in10)
;  l6 complex points
;  Initial delay is in10: gives (90,-180) phase distortion in F1.
;ns=8, 16, ..., ds=8, 16,...
;
;Recommendations for gradients:
;gpz1:  12%
;gpz2:  22%
;gpz3:  14%
;gpx4:  27% (adjust for magic-angle)
;gpz4:  15%
;gpx5:  27% (adjust for magic-angle)
;gpz5:  15%
;gpx6:  12%
;gpy7:  12%
;gpnam1: sine.50
;gpnam2: sine.100
;gpnam3: sine.32
;gpnam4: sine.100
;gpnam5: sine.100
;gpnam6: sine.50
;gpnam7: sine.32
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
#define H1_EVOL		; comment out for 2D w/o H1 evolution
#define C13_EVOL	; comment out for 2D w/o C13 evolution
#define EXPTCORR	; uncomment if you want "expt" to report
			; the correct exp. time (works with XWIN-NMR 2.x)

;Define channel assignments:
#define H f1
#define N f2
#define C f3
;
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef H1_EVOL
#undef C13_EVOL
#endif


define delay TAUA
define delay TAUA1
define delay TAUA7
define delay TAUB
define delay TAUB3
define delay TAUC
define delay TAUC6
define delay TAUD
define delay CEN_HC1
define pulse H1_90
define pulse H1_180
define pulse N15_90
define pulse N15_180
define pulse C13_90
define pulse C13_180
define pulse CO_180
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7

"H1_90=p1"
"H1_180=H1_90*2"
"N15_90=p2"
"N15_180=N15_90*2"
"C13_90=p3"
"C13_180=C13_90*2"
"CO_180=p5"
;
"GRAD1=500u"
"GRAD2=2m"
"GRAD3=300u"
"GRAD4=7m"
"GRAD5=4.4m"
"GRAD6=500u"
"GRAD7=300u"
;
"d11=100m"
"d12=10u"
"d13=5u"
"d14=60u"
"d16=300u"
"TAUA=1.6m"
"TAUB=475u"
"TAUC=1.1m"
"TAUD=3.25m"
"TAUA1=TAUA-GRAD1"
"TAUA7=TAUA-GRAD7"
"TAUB3=TAUB-GRAD3-CO_180/2"
"TAUC6=TAUC-GRAD6"

"d0=d13"
#ifdef C13_EVOL
  "d10=(in10/2)+d13"
#else
  "d10=d13"
#endif
"d23=C13_90*4+d13*4"
"d24=H1_90+N15_90+d13"
"CEN_HC1=C13_90-H1_90"

#ifdef EXPTCORR
  "d31=2*(TAUA1+GRAD1+2*TAUB3+2*GRAD3+TAUD+TAUC6+GRAD6+TAUA7+GRAD7)+GRAD2+GRAD4+GRAD5"
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d13
  d14 do:C
  d11 LOCKH_OFF
3 d14
  d14
  d14
4 d14
  d14
5 d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d1 pl1:H pl3:C
  d13 LOCKH_ON
  d13 UNBLKGRAMP
;------------------ INEPT to C and H1_EVOL -------------------
  (H1_90 ph11):H
  d13
  GRAD1:gp1		; 500u, 8G/cm
  TAUA1
  d0
  (C13_90 ph0 d13 C13_180 ph1 d13 C13_90 ph0):C
  d0
  (H1_180 ph0):H
  d13
  GRAD1:gp1		; 500u, 8G/cm
  TAUA1
  d23
  (H1_90 ph1):H
  d13
  GRAD2:gp2		; 2.0m, 15G/cm
  d16                                                       
;------------------ Refocus C and C13_EVOL -------------------
  (C13_90 ph12):C
  d10
  (N15_180 ph0):N
  d13
  GRAD3:gp3		; 300u, 10G/cm
  TAUB3 pl0:C
  (CO_180:sp5 ph0):C
  d13
  GRAD3:gp3		; 300u, 10G/cm
  TAUB3 pl3:C
  (H1_180 ph0):H
  d10
  (C13_180 ph0):C
  d13
  GRAD3:gp3		; 300u, 10G/cm
  TAUB3 pl0:C
  d24
  (CO_180:sp5 ph0):C
  d13
  GRAD3:gp3		; 300u, 10G/cm
  TAUB3 pl3:C
  d24
  (C13_90 ph0):C
  TAUD
  (C13_180 ph0):C
  TAUD
  (C13_90 ph1):C
  d12 pl10:H
  (p10*2 ph0 d13 p10*1.4 ph1):H
  d13
  GRAD4:gp4		; 7.0m, 30G/cm
  d16 pl1:H
  (H1_90 ph0):H
  d13
  GRAD5:gp5		; 4.4m, 30G/cm
  d16
  (C13_90 ph1):C
  d13
  GRAD6:gp6		; 500u, 8G/cm
  TAUC6
  (C13_180 ph0):C (CEN_HC1 H1_180 ph0):H
  d13
  GRAD6:gp6		; 500u, 8G/cm
  TAUC6
  (C13_90 ph0):C
  (H1_90 ph0):H
  d13
  GRAD7:gp7		; 300u, 8G/cm
  TAUA7
  (C13_180 ph0):C (CEN_HC1 H1_180 ph0):H
  d13
  GRAD7:gp7		; 300u, 8G/cm
  TAUA7
;----- Suppress water and C decoupling sideband modulation ---
  (H1_90 ph0):H (C13_90 ph0 d13 C13_90 ph13):C
  d13 BLKGRAMP
  d12 pl13:C
  go=2 ph31 cpds3:C

#ifdef ONE_D
  d11 do:C wr #0 
  d13 LOCKH_OFF
#else
  d11 do:C wr #0 if #0 zd
  d13 LOCKH_OFF
#endif
#ifdef H1_EVOL
  d14 ip11
  lo to 3 times 2
  d14 id0 
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd0
#endif
#ifdef C13_EVOL
  d14 ip12 
  lo to 5 times 2
  d14 id10
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 2
ph12=0 0 2 2
ph13=0 0 0 0 2 2 2 2
ph31=0 2 2 0