;hn15noegp.fa
;2D 1H-15N-NOE, using echo-antiecho gradient coherence selection,
; using the gp gradient syntax
; NOE and no-NOE (control) experiments are recorded interleaved
;Farrow et al., Biochemistry 33, 5984-6003 (1994).
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
; $Id: hn15noegp.fa,v 1.2 2000/10/26 22:19:28 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm
;
;p1 90 H1 at pl1
;p2 90 N15 at pl2
;pl0 120dB
;d1: relaxation delay, 5 sec.
;
;
;N15 Waltz-16 PCPD2 at pl12, cpdprg2
;N15 evolution:
;  in0, SW(N)=1/(2*in0)
;  l4 complex points in each  2D (ser file holds two 2D files)
;     - set "1 td" to 4*l4.
;  The NOE enhanced 2D is in rows 1,2,5,6,9,10,...
;  The reference 2D spectrum is in rows 3,4,7,8,11,12,...
;  Quadrature dection in t1 by echo-antiecho, with axial peaks
;  at the edge of the spectrum.
;  DW(N)/2 initial delay ((90,-180) phase distortion in F1)
;
;ns=8, 16, ..., ds=8, 16, ...
;
;Recommendations for gradients:
;gpz5: -44%
;gpx6:  54%
;gpz6:  30%
;gpx7:  14%
;gpy8:  20%
;gpx9:  54%
;gpz9:  30%
;gpnam5: sine.100
;gpnam6: sine.100
;gpnam7: sine.50
;gpnam8: sine.50
;gpnam9: sine.20
;
;Coherence selection gradient pair (GRAD6/GRAD9) may be optimized
;by varying p19 (uncomment OPTIM_P19). Theoretical value of p19 is 131.7 us.
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
;#define NOE		; uncomment for NOE in 1D experiment
;#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD9)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;You shouldn't have to worry about anything beyond this point :-)
;
;Define channel assignments:
#define H f1
#define N f2
;
;Sanity checks
#ifndef ONE_D
#undef NOE
#endif
;
define delay TAUA
define delay TAUA7
define delay TAUA8
define delay TAUB
define delay TAUB2
define delay TAUC
define delay SATDEL
define delay RDEL1
define delay RDEL2
define delay RDEL3
define delay RDEL4
define pulse H1_90
define pulse H1_120
define pulse H1_180
define pulse N15_90
define pulse N15_180
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD8
define pulse GRAD9

"d11=100m"			;disk i/o
;"d12=10u"			;power switching etc.
"d13=5u"			;a short delay
"d14=60u"			;ip,id etc.
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_120=H1_90*4/3"
"H1_180=H1_90*2"
"N15_90=p2"
"N15_180=N15_90*2"

"GRAD5=1.5m"
"GRAD6=1.3m"
"GRAD7=500u"
"GRAD8=500u"
#ifndef OPTIM_P19
  "p19=131.7u"
#endif
"GRAD9=p19"

#ifdef ONE_D
  "d0=d13"
#else
  "d0=d13+in0/2"
#endif

"TAUA=2.25m"			;1/(4Jnh) w/ relax. comp.
"TAUA7=TAUA-GRAD7-d13-d16"
"TAUA8=TAUA-GRAD8-d13-d16"
"TAUB=2.75m"
"TAUB2=TAUB-GRAD6-d16-H1_180-d13*2"
"TAUC=500u"
"d6=H1_90"
"d7=N15_90"
"d25=TAUC-GRAD9-d13"
"d29=N15_90-H1_90"
"SATDEL=3s"
"RDEL3=5m"
"l1=SATDEL/(H1_120+RDEL3)"
"RDEL2=d1-(l1*(H1_120+RDEL3))"
"RDEL1=d1"
"RDEL4=7s"
#ifdef NOE
  "l0=1"
#else
  "l0=0"
#endif
#ifdef EXPTCORR
  "d31=2*(TAUA7+GRAD7+TAUA8+GRAD8)+RDEL1+TAUB+TAUB2+TAUC+GRAD5+GRAD6+GRAD9"
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d13 do:N
  d11 LOCKH_OFF
  3m
  d14
  d14
3 d14
  d14
  d14
  d14
  d14
4 d14 LOCKH_OFF
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  
  d14 pl1:H pl2:N
  if "l0 %2 == 0" goto 9
  RDEL2
8 (H1_120 ph0):H
  RDEL3
  lo to 8 times l1
  d13
  goto 10
9 RDEL1
  d13 
10 d13 LOCKH_ON
  d13 UNBLKGRAMP
  (H1_90 ph0):H
  d13
  GRAD5:gp5		;1.5m, -30G/cm
  d16
  (N15_90 ph12):N
  TAUB
  (N15_180 ph13):N
  d0
  (H1_180 ph0):H
  d0
  TAUB2
  GRAD6:gp6*EA		;1.3m, +/-30G/cm
  d16
  (N15_90 ph14):N
  d6
  (H1_90 ph0):H
  d13
  GRAD7:gp7		;500u, 7G/cm
  d16
  TAUA7
  (N15_180 ph0):N
  (H1_180 ph0):H 
  d13
  TAUA7
  GRAD7:gp7		;500u, 7G/cm
  d16
  d7
  (N15_90 ph1):N
  (H1_90 ph1):H 
  d13
  GRAD8:gp8		;500u, 7G/cm
  d16
  TAUA8
  (d29 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA8
  GRAD8:gp8		;500u, 7G/cm
  d16
  (H1_90 ph2):H
  TAUC pl12:N
  (H1_180 ph0):H
  d13
  GRAD9:gp9		;130u, 30G/cm
  d25 BLKGRAMP
  go=2 ph31 cpd2:N

#ifdef ONE_D
  d11 do:N wr #0
  d13 LOCKH_OFF
#else
  d11 do:N wr #0 if #0 zd
  d13 LOCKH_OFF
  3m igrad EA
  d14 ip14
  d14 ip14
  lo to 3 times 2
  ; insert ~7 s extra to let 1H relax before NO-NOE
  RDEL4 iu0
  lo to 3 times 2
  d14 id0 
  d14 ip12
  d14 ip12
  d14 ip31
  d14 ip31
  lo to 4 times l4
#endif

  
exit
  
ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 0
ph12=1 3
ph13=0 0 1 1 2 2 3 3
ph14=0
ph31=0 2 2 0