;hncacof.fa
;3D HN(CA)CO with Watergate (3-9-19) reverse INEPT (FHSQC) 
;   and optional 2H decoupling
;This version makes use of the gp gradient syntax.
;Matsuo et al., J. Magn. Reson. B 110, 112-115 (1996)
;Mori et al., J. Magn. Reson. B 108, 94-98 (1995)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hncacof.fa,v 1.1 2002/10/30 20:59:19 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C, f5: 2H (channel assignments may be changed below)
;o1p: 4.7 ppm,
;o2p: 118 ppm,
;o3p: use fq3list fahncacof.C: CA,CO,CA (55 ppm, 176 ppm, 55 ppm)
;o5p:: 4.5 ppm
;
;d1: relaxation delay = d1+0.1s
;p1 90 H at pl1
;p11 90 2.0 ms H1 semi-selective H2O flip-back pulse at power:
;  1) pl21 (zgsel1.fa), with phcor21;
;  2) pl22 (zgsel2.fa), with phcor22.
;  Check for a possible phase difference between hard H1 and soft H1
;  pulses and set phcor21 and phcor22 accordingly.
;p10 90 H at pl10 (H1 composite decoupling)
;p2 90 N at pl2
;p3  90 dgr. CO/Ca at pl3 for 90 dgr. regular semi-selective:
;   field strength=dNu/sqrt(15), dNu=(176ppm-55ppm)*bf3. p3 54.4 us at 600 MHz. 
;p4 90 dgr. Ca at pl4 for 180 dgr. regular semi-selective:
;   field strength=dNu/sqrt(3),	dNu=(176ppm-55ppm)*bf3. p4 24.4 us at 600 MHz.
;  (Any phase difference between pl3 and pl4 will result in loss of signal.
;   Run CORTAB on your system to minimize phase differences between different
;   power levels).
;p5 180 dgr. CO square shaped (spnam5) at power sp5, offset CO-Ca,
;   semi-selective: field strength=dNu/sqrt(3),	dNu=(176ppm-55ppm)*bf3.
;   p5 48.8 us at 600 MHz.
;p8 180 dgr. Ca square shaped (spnam8) at power sp8, offset Ca-CO,
;   semi-selective: field strength=dNu/sqrt(3),	dNu=(176ppm-55ppm)*bf3.
;   p8 48.8 us at 600 MHz.
;p25 90 2H pulse at pl15 (optional)
;pl0 120dB
;d21: 1/(2*dNu), dNu=Nu(NH)-Nu(H2O)
;
;H1  Waltz-16x or DIPSI-2x (cpdprg1), using p90 (PCPD1) at pl10
;N15 Waltz-16 (cpdprg2), using p90 (PCPD2) at pl12
;CO  Compensated SEDUCE1 decoupling of CO, using pcpd3 at sp3,
;    shape seduce1c5/6, offset 0, cpdprg3 waltz16sp3.
;H2  Waltz-16 (cpdprg4/5), using p90 (PCPD4/5) at pl15
;N15 evolution:
;  in10=in30, SW(N)=1/2*in10
;  l4 complex points; max. is (d10/in10)+1
;  Process as States (although data is acquired as States-TPPI)
;  N15 chemical shift axis is reversed: set reverse to true.
;C13 evolution:
;  in0, SW(C)=1/2*in0
;  l6 complex points
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F1.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;ns=16, 32, ..., ds=16, 32, ...
;or ns=(4), 8, ..., ds=8, 16, ... if SHORTPHC defined below
;
;Recommendations for triple-axis (single-axis) gradients:
;gpz1:  15% (15%)
;gpz2:   6% (6%)
;gpz3:  15% (15%)
;gpz4:  8% (8%)
;gpz5:  15% (15%)
;gpz6:  12% (12%)
;gpx7:  54% adjust for magic angle (0%)
;gpz7:  30% (55%)
;gpz8:  22% (22%)
;gpz9:  15% (15%)
;gpz10: 15% (15%)
;gpz11: 29% (29%)
;gpnam1: sine.100
;gpnam2: sine.50
;gpnam3: sine.100
;gpnam4: sine.100
;gpnam5: sine.50
;gpnam6: sine.50
;gpnam7: sine.100
;gpnam8: sine.10
;gpnam9: sine.100
;gpnam10: sine.50
;gpnam11: sine.10
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
#define N15_EVOL	; comment out for 2D w/o N15 evolution
#define C13_EVOL	; comment out for 2D w/o C13 evolution
;#define H2_DEC		; uncomment to enable H2 decoupling
;#define SHORT_P2	; uncomment if p5/2 > p2
#define SHORTPHC	; uncomment for 8 (4) step phase cycle
#define CRP		; uncomment for use on CryoProbe (no sim. N15,C13 pulses)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
#define D f5
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef N15_EVOL
#undef C13_EVOL
#endif
;
aqseq 321
;
define delay TAUA
define delay TAUA2
define delay TAUA7
define delay TAUB
define delay TAUC
define delay TAUC1
define delay TAUE
define delay TAUE8
define delay TAUE11
define delay TAUW
define delay TAUW1
define delay TN
define delay CEN_HN1
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD8
define pulse GRAD9
define pulse GRAD10
define pulse GRAD11
define pulse H1_90
define pulse H1_180
define pulse H1_S90
define pulse N15_90
define pulse N15_180
define pulse CA_90
define pulse CA_180
define pulse CAO_180
define pulse CO_90
define pulse COA_180

"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;a short delay
"d14=20u"			;ip,id etc.
"d16=300u"			;gradient recovery
"d17=50u"                       ;short gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"H1_S90=p11"
"N15_90=p2"
"N15_180=N15_90*2"
"CA_90=p3"
"CA_180=p4*2"
"CAO_180=p8"
"CO_90=p3"
"COA_180=p5"

"GRAD1=700u"
"GRAD2=500u"
"GRAD3=1.0m"
"GRAD4=1.0m"
"GRAD5=600u"
"GRAD6=500u"
"GRAD7=700u"
"GRAD8=100u"
"GRAD9=700u"
"GRAD10=600u"
"GRAD11=80u"

"d6=H1_90"
"TAUW=d21"
"TAUA=2.3m"
"TAUB=5.4m"
"TAUC=12.4m"
"TAUE=4.5m"
"TN=12.4m"

"TAUA2=TAUA-GRAD2-d13-d16"
"TAUA7=TAUA-TAUW*2.5-H1_90*2.385-GRAD7-d16-d13"
"TAUC1=TAUC-TAUB-p10-d13*2-d12"
#ifdef H2_DEC
  "TAUE8=TAUE-GRAD8-d17-COA_180-p10-p25-d12*3-d13*5"
  "TAUE11=TAUE-GRAD11-d17-COA_180-p10-p25-d12*3-d13*5"
#else
  "TAUE8=TAUE-GRAD8-d17-COA_180-p10-d12*2-d13*5"
  "TAUE11=TAUE-GRAD11-d17-COA_180-p10-d12*2-d13*5"
  ; H1_DEC_ON/OFF: p10+d12+d13*2
  ; H2_DEC_ON: p25+d12+d13 or d13
  ; H2_DEC_OFF: p25+d12+d13 or d13
#endif
"TAUW1=(TAUW/2)-N15_90"

"d10=TN-d13*3-d12"
"d30=TN-TAUB-CA_180-p10-d12*3-d13*6"

#ifdef CO_EVOL
#ifdef CRP
  "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-N15_180-d12*2-d13*2)/2"
#else
#ifdef SHORT_P2
  "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-d12*2-d13*2)/2"
#else
  "d0=((cnst0*2+1)*in0-CO_90*1.273-N15_180-d12*2-d13*2)/2"
#endif
#endif
#endif

"CEN_HN1=N15_90-H1_90"


#define H1_DEC_ON d13 \n d12 pl10:H \n p10:H ph1 \n d13 cpds1:H

#define H1_DEC_OFF d13 do:H \n p10:H ph3 \n d13 \n d12 pl1:H

#define H1_DEC_OFF_Y d13 do:H \n p10:H ph1 \n d13 \n d12 pl1:H

#ifdef H2_DEC
#define H2_DEC_ON d12 pl15:D \n p25:D ph1 \n d13 cpds5:D
#define H2_DEC_OFF d13 do:D \n p25:D ph3 \n d12
#else
#define H2_DEC_ON d13
#define H2_DEC_OFF d13
#endif

#define SED_ON d13 \n d12 pl0:C \n d13 cpds3:C

#define SED_OFF d13 do:C

#ifdef EXPTCORR
  "d31=2*(TAUA2+GRAD2+TAUB+TAUA7+GRAD7+2*TAUW+TAUW1)+GRAD1+GRAD3+TAUC1+TAUC+GRAD4+GRAD5+GRAD6"
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
  d11 LOCKDEC_ON
2 d13 do:N
  d13 H2_LOCK
  d11 LOCKH_OFF
  d14
3 d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif  
  d1 pl1:H pl2:N
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  d13 H2_PULSE
  (N15_90 ph0):N
  d13
  GRAD1:gp1		; 400 us, 10G/cm, sine.50
  d16 fq3:C
; INEPT transfer from H to N
  (H1_90 ph0):H
  d13
  GRAD2:gp2		; 500 us, 4G/cm, sine.50
  d16
  TAUA2
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA2
  GRAD2:gp2		; 500 us, 4G/cm, sine.50
  d16
  (H1_90 ph1):H
  (d13 d12 pl22 H1_S90 ph22:r d13 d12 pl1):H	;2ms 90 H1 pulse at phase x
  d13
  GRAD3:gp3		; 1.0 ms, 10G/cm, z, sine.100
  d16
; INEPT transfer from N to CA and refocus H
  (N15_90 ph11):N
  TAUB
  H1_DEC_ON
  TAUC1 pl4:C
  (N15_180 ph0):N
  (TAUC) (d13 CA_180 ph0):C
  (N15_90 ph0):N
  H1_DEC_OFF
  d13
  GRAD4:gp4*-1		; 1.0 ms, -5G/cm, sine.100
  d16 pl3:C
  H1_DEC_ON
  H2_DEC_ON
  (CA_90 ph12):C
  (d13 d12 pl0 COA_180:sp5 ph0):C
  d13
  TAUE8
  H2_DEC_OFF
  H1_DEC_OFF
  GRAD8:gp8		; 100 us, 15G/cm, sine.10
  d17 pl4:C
  (CA_180 ph0):C
  (d13 d12 pl0 COA_180:sp5 ph0):C
  d13
  GRAD8:gp8		; 100 us, 15G/cm, sine.10
  d17 pl3:C
  H1_DEC_ON
  H2_DEC_ON
  TAUE8
  (CA_90 ph13):C
  H2_DEC_OFF
  H1_DEC_OFF
  GRAD9:gp9		; 700 us, 10G/cm, sine.100
  d16 fq3:C
  d13
  d12 pl3:C
; CO evolution (t1)
  (CO_90 ph14):C
  d13
#ifdef C13_EVOL
  d12 pl0:C
#ifdef CRP
  (d0 CAO_180:sp8 ph0):C
  (d13 N15_180 ph0 d0):N
  d12 pl3:C
#else
  (d0 CAO_180:sp8 ph0 d0):C (d0 N15_180 ph0 d0):N
  d13
  d12 pl3:C
#endif
#endif
  (CO_90 ph0):C
  d13
  GRAD10:gp10		; 600 us, 10G/cm, sine.50
  d16 fq3:C
  d13
  d12 pl3:C
  H1_DEC_ON
  H2_DEC_ON
  (CA_90 ph1):C
  (d13 d12 pl0 COA_180:sp5 ph0):C
  d13
  TAUE11
  H2_DEC_OFF
  H1_DEC_OFF
  GRAD11:gp11		; 80 us, 20G/cm, sine.10
  d17 pl4:C
  (CA_180 ph0):C
  (d13 d12 pl0 COA_180:sp5 ph0):C
  d13
  GRAD11:gp11		; 80 us, 20G/cm, sine.10
  d17 pl3:C
  H1_DEC_ON
  H2_DEC_ON
  TAUE11
  (CA_90 ph0):C
  H2_DEC_OFF
  H1_DEC_OFF
  d13
  GRAD5:gp5		; 600u s, 10G/cm, sine.50
  d16
  H1_DEC_ON
; Begin constant time evolution on N (t2)
  (N15_90 ph15):N
  SED_ON
  d10
  SED_OFF
  (N15_180 ph16):N
  (d13 d12 pl4 CA_180 ph0):C
  SED_ON
  d30
  H1_DEC_OFF
  TAUB
  SED_OFF
  (N15_90 ph0):N
  d13
  GRAD6:gp6		; 500 us, 8G/cm, sine.50
  d16
  (d13 d12 pl21 H1_S90 ph21:r d13 d12 pl1):H	;2ms 90 H1 pulse at phase x
  (H1_90 ph2):H
  d13
  TAUA7
  GRAD7:gp7		; 700 us, 40G/cm, sine.100
  d16
  (H1_90*0.231 ph1):H
  TAUW
  (H1_90*0.692 ph1):H
  TAUW
  (H1_90*1.462 ph1):H
  TAUW1
  (N15_180 ph0):N
  TAUW1
  (H1_90*1.462 ph3):H
  TAUW
  (H1_90*0.692 ph3):H
  TAUW
  (H1_90*0.231 ph3):H
  d13
  GRAD7:gp7		; 700 us, 40G/cm, sine.100
  d16 pl12:N
  TAUA7
  d6 BLKGRAMP
  go=2 ph31 cpds2:N

#ifdef ONE_D
  d11 do:N wr #0 H2_LOCK
#else
  d11 do:N wr #0 if #0 zd H2_LOCK
#endif
  d13 LOCKH_OFF
#ifdef N15_EVOL
  d14 ip15
  lo to 3 times 2
  d14 dd10
  d14 id30
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd10
  d14 rd30
#else
  d14*7
#endif
#ifdef C13_EVOL
  d14 ip14
  lo to 5 times 2
  d14 id0 
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif

  d14 LOCKDEC_OFF

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph21=0
ph22=0
#ifdef SHORTPHC
ph11={0}*4 {2}*4
ph12=0 2
ph13=1 1 3 3
ph14=0 0 2 2
ph15=0
ph16=0 0 2 2
ph31=0 2 0 2  2 0 2 0
#else
ph11=0 2
ph12=0 0 2 2
ph13=1 1 1 1 3 3 3 3
ph14=0 0 0 0 0 0 0 0  2 2 2 2 2 2 2 2
ph15=0
ph16=0 0 0 0 2 2 2 2
ph31=0 2 2 0 2 0 0 2  2 0 0 2 0 2 2 0
#endif