;hncacotrb.fa
;4D TROSY-HNCACO using two separate pulses for 180 Ca/C'.
;Yang and Kay, J. Am. Chem. Soc. 1999, 121, 2571-2575.
;Bruker Avance/Xwin-nmr version. This program requires XWIN-NMR 2.5+
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hncacotrb.fa,v 1.2 2001/07/13 00:23:37 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C, f5: 2H (channel assignments may be changed below)
;o1p: 4.7 ppm
;o2p: 118 ppm,
;o3p: use fq3list fahncacotr.C (55 ppm, 176 ppm, 55 ppm)
;o5p: 4.5 ppm
;
;d1: relaxation delay = d1+0.1s
;p1 90 H at pl1
;p2 90 N at pl2
;p3  90 dgr. CO/Ca at pl3 for 90 dgr. rectangular semi-selective:
;   field strength=dNu/sqrt(15), dNu=(176ppm-55ppm)*bf3. p3 54.4 us at 600 MHz. 
;p4 90 dgr. Ca at pl4 for 180 dgr. rectangular semi-selective:
;   field strength=dNu/sqrt(3),	dNu=(176ppm-55ppm)*bf3. p4 24.4 us at 600 MHz.
;p5 180 dgr. CO rectangular shaped (spnam5) at power sp5, offset CO-Ca,
;   semi-selective: field strength=dNu/sqrt(3),	dNu=(176ppm-55ppm)*bf3.
;   p5 48.8 us at 600 MHz.
;p6 180 dgr. shaped Ca refocusing REBURP (spnam6 reburp.256) pulse.
;   p6 = (1000/y) ms, where y is the spectrometer frequency in MHz
;   (1.6ms at 600, 1.3ms at 750).
;p7 180 dgr. shaped Ca refocusing REBURP (spnam7 reburp.256) pulse.
;   p7 = 350us x (600/y), where y is the spectrometer frequency in MHz
;   (280us at 750).
;p8 180 dgr. Ca rectangular shaped (spnam8) at power sp8, offset Ca-CO,
;   semi-selective: field strength=dNu/sqrt(3),	dNu=(176ppm-55ppm)*bf3.
;   p8 48.8 us at 600 MHz.
;p11 90 H1 shaped (spnam1, EBURP-1) H2O pulse at power sp1, offset 0.
;   p11 ~ 7 ms. Check for a possible phase difference between hard H1 and
;   soft H1 pulses and set the phase program ph21 accordingly.
;p25 90 dgr. 2H pulse at pl15   
;pl0 120dB
;
;H2 Waltz-16 (cpdprg5) decoupling, 90 dgr. pulse (PCPD) at pl15
;N15 evolution:
;  in10=in30, SW(N)=1/(2*in10), typ. 30-40 ppm
;  l4 complex points; max. is (d10/in10)+1
;  Process as echo-antiecho.
;  Chemical shift axis is reversed.
;CO evolution:
;  in0, SW(CO)=1/(2*in0), typ. 11 ppm
;  l6 complex points.
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase error in F1.
;  cnst0=1 gives (270,-540) phase error in F1 (use LP to correct).
;Ca evolution:
;  in19=in20=in21, SW(Ca)=1/(2*in20), typ. 18 ppm
;  l8 complex points. Max. l8 is d19/in19.
;  define CA_DW2 (below) for DW/2 initial delay (90,-180 phase).
;ns=4, 8, ..., ds=4, 8,...
;
;Recommendations for gradients:
;gpz1:   7%
;gpz2:  15%
;gpz3:  15%
;gpz4:  22%
;gpz5: -22%
;gpz6:  18%
;gpz7:  29%
;gpz8:  22%
;gpx9:  54% adjust for magic angle
;gpz9:  30%
;gpz10:  5%
;gpz11:  8%
;gpx12: 54% adjust for magic angle
;gpz12: 30%
;gpnam1: sine.50
;gpnam2: sine.100
;gpnam3: sine.100
;gpnam4: sine.10
;gpnam5: sine.50
;gpnam6: sine.50
;gpnam7: sine.10
;gpnam8: sine.50
;gpnam9: sine.100
;gpnam10:sine.50
;gpnam11:sine.50
;gpnam12:sine.32
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
#define N15_EVOL	; comment out for 2D w/o N15 evolution
#define CA_EVOL		; comment out for 2D or 3D w/o CA evolution
#define CO_EVOL		; comment out for 2D or 3D w/o CO evolution
#define CA_DW2		; uncomment for an initial delay of dw/2 in t1 (CA)
#define H2_DEC		; uncomment if 2H labeled sample
;#define SHORT_P2	; uncomment if p8/2 > p2
#define CRP		; uncomment for use on CryoProbe (no sim. N15,C13 pulses)
#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD12)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
#define D f5
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef N15_EVOL
#undef CA_EVOL
#undef CO_EVOL
#endif
#ifndef CA_EVOL
#undef CA_DW2
#endif
;
;
define delay DELTA
define delay TAUA
define delay TAUA1
define delay TAUA10
define delay TAUA11
define delay TAUB
define delay TC
define delay TAUC
define delay TAUC7
define delay TN
define delay TN2
define delay CEN_HN1
define pulse H1_90
define pulse H1_180
define pulse H1_S90
define pulse N15_90
define pulse N15_180
define pulse CA_90
define pulse CA_180
define pulse CO_90
define pulse COA_180
define pulse CAO_180
define pulse CA_REBP
define pulse CA2REBP
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD8
define pulse GRAD9
define pulse GRAD10
define pulse GRAD11
define pulse GRAD12

"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;just a short delay
"d14=80u"			;ip,id etc
"d16=300u"			;gradient recovery
"d17=50u"			;short gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"H1_S90=p11"
"N15_90=p2"
"N15_180=N15_90*2"
"CA_90=p3"
"CA_180=p4*2"
"CAO_180=p8"
"CO_90=p3"
"COA_180=p5"
"CA_REBP=p6"
"CA2REBP=p7"
;
"GRAD1=400u"
"GRAD2=1.0m"
"GRAD3=700u"
"GRAD4=100u"
"GRAD5=600u"
"GRAD6=500u"
"GRAD7=80u"
"GRAD8=400u"
"GRAD9=3.000m"
"GRAD10=400u"
"GRAD11=400u"
#ifndef OPTIM_P19
"p19=305u"			; configurable: set to the optimum value on your instrument
#endif
"GRAD12=p19"

"TAUA=2.2m"			; configurable: ~1/(4*JNH)
"TAUA1=TAUA-GRAD1-d16-d13"
"TAUA10=TAUA-GRAD10-d16-d13"
"TAUA11=TAUA-GRAD11-d16-d13"
"TAUB=12.0m"			; configurable: usually 12ms
"TC=8.2m"
#ifdef CA_DW2
  "d19=TC/4-d12-d13-in20/2"
  "d20=TC/4-GRAD4-d17-p25*2-COA_180-d12*3-d13*4+in20/2"
  "d21=d20-COA_180-d12-d13+in20/2"
#else
  "d19=TC/4-d12-d13"
  "d20=TC/4-GRAD4-d17-p25*2-COA_180-d12*3-d13*4"
  "d21=d20-COA_180-d12-d13"
#endif
"TAUC=4.0m"
"TAUC7=TAUC-GRAD7-d17-COA_180-d12*2-d13*3-p25"
"TN=12.0m"			; configurable: usually 12ms
"d10=TN"
"d30=d13"
"TN2=TN-d13-GRAD9-d16-COA_180-d30"
"DELTA=GRAD12+d16+d13*2"
"CEN_HN1=N15_90-H1_90"

#ifdef CO_EVOL
#ifdef CRP
 "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-N15_180-d12*2-d13*2)/2"
#else
#ifdef SHORT_P2
 "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-d12*2-d13*2)/2"
#else
 "d0=((cnst0*2+1)*in0-CO_90*1.273-N15_180-d12*2-d13*2)/2"
#endif
#endif
#endif

#ifdef EXPTCORR
  "d31=2*(TAUA1+TAUB+TAUA10+TAUA11+TAUC7+GRAD1+GRAD4+GRAD7+GRAD10+GRAD11)+GRAD2+GRAD3+GRAD5+GRAD6+GRAD8+GRAD9+TN2+DELTA+GRAD12"
#endif

#ifdef H2_DEC
#define H2_DEC_ON d12 pl15:D \n p25:D ph1 \n d13 cpds5:D
#define H2_DEC_OFF d13 do:D \n p25:D ph3 \n d12
#else
#define H2_DEC_ON d13
#define H2_DEC_OFF d13
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
  d11 LOCKDEC_ON
2 d13
  d14 H2_LOCK
  d11 LOCKH_OFF
  3m
  d14
3 d14
  d14
  d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d14
  d14
7 d14
  d14
  d14
  d14
  d14
8 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif  
  d1 pl2:N
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  d13 H2_PULSE
  d14 fq3:C
  d13
; INEPT transfer from H to N
  (d13 d12 pl0 H1_S90:sp1 ph21 d13 d12 pl1):H	;Selective 90 H1 pulse phase -y
  (H1_90 ph0):H
  d13
  GRAD1:gp1		; 0.4ms, 5G/cm, z, sine.50
  d16
  TAUA1
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA1
  GRAD1:gp1		; 0.4ms, 5G/cm, z, sine.50
  d16
  (H1_90 ph19):H	; phase y on Bruker DMX
  d13
  GRAD2:gp2		; 1.0ms, 10G/cm, z, sine.100
  d16 
; INEPT transfer from N to CO
  (N15_90 ph0):N
  TAUB pl4:C
  (N15_180 ph0):N
  (TAUB) (d13 CA_180 ph0):C
  (N15_90 ph1):N
  d13
  GRAD3:gp3		; 700us, 10G/cm, z, sine.100
  d16 pl3:C
  H2_DEC_ON
  (CA_90 ph11):C
  d13
  d19
  d12 pl0:C
  (CA2REBP:sp7 ph0 d13 d12 pl0):C
  (COA_180:sp5 ph0):C
  d13
  H2_DEC_OFF
  GRAD4:gp4		; 100us, 15G/cm, z, sine.10
  d17
  H2_DEC_ON
  d21 pl0:C
  (COA_180:sp5 ph0 d13 d12 pl0):C
  (CA_REBP:sp6 ph12):C
  d13
  d19
  d12 pl0:C
  (CA2REBP:sp7 ph0 d13 d12 pl0):C
  (COA_180:sp5 ph0):C
  d13
  H2_DEC_OFF
  GRAD4:gp4*-1		; 100us, -15G/cm, z, sine.10
  d17 pl3:C
  H2_DEC_ON
  d20
  (CA_90 ph1):C
  H2_DEC_OFF
  GRAD5:gp5		; 600us, -15G/cm, z, sine.50
  d16 fq3:C
  d13
  d12 pl3:C
; Begin CO evolution (t2)
  (CO_90 ph13):C
  d13
#ifdef CO_EVOL
  d12 pl0:C
#ifdef CRP
  (d0 CAO_180:sp8 ph0):C
  (d13 N15_180 ph0 d0):N
  d12 pl3:C
#else
  (d0 CAO_180:sp8 ph0 d0):C (d0 N15_180 ph0 d0):N
  d13
  d12 pl3:C
#endif
#endif
  (CO_90 ph0):C
; End CO evolution
  d13
  GRAD6:gp6		; 500us, 12G/cm, z, sine.50
  d13
  d16 fq3:C
  H2_DEC_ON
  d12 pl3:C
  (CA_90 ph0):C
  TAUC7
  H2_DEC_OFF
  d13
  GRAD7:gp7		; 80us, 20G/cm, z, sine.10
  d17 pl0:C
  (COA_180:sp5 ph0 d13 d12 pl0):C
  (CA_REBP:sp6 ph0):C
  d13
  GRAD7:gp7		; 80us, 20G/cm, z, sine.10
  d17
  H2_DEC_ON
  TAUC7 pl0:C
  (COA_180:sp5 ph0 d13 d12 pl3):C
  (CA_90 ph1):C
  H2_DEC_OFF
  d13
  GRAD8:gp8		; 400us, 15G/cm, z, sine.50
  d16 pl4:C
; Begin constant time evolution on N (t3)
  (N15_90 ph14):N
  d10
  (N15_180 ph15):N
  (TN2) (d13 CA_180 ph0):C
  d13
  GRAD9:gp9*EA*-1	; 3.000 ms, -/+30G/cm, ma, sine.100
  d16 pl0:C
  (COA_180:sp5 ph0):C
  d30
; End constant time
; Sensitivity enhanced coherence transfer from N to H
  (N15_90 ph16):N
  (H1_90 ph0):H
  d13
  GRAD10:gp10		; 0.4ms, 3.1G/cm, z, sine.50
  d16
  (TAUA10) (d12 pl3 d13 CA_90 ph0):C	; Purge CA
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA10
  GRAD10:gp10		; 0.4ms, 3.1G/cm, z, sine.50
  d16
  (H1_90 ph1):H
  d13
  (N15_90 ph1):N
  d13
  GRAD11:gp11		; 0.4ms, 5.35G/cm, z, sine.50
  TAUA11
  d16
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA11
  GRAD11:gp11		; 0.4ms, 5.35G/cm, z, sine.50
  d16
  (N15_90 ph0):N
  d13
  (H1_90 ph0):H
  DELTA
  (H1_180 ph0):H
  d13
  GRAD12:gp12		; 305u, 30G/cm, ma, sine.32
  d13
  d16 BLKGRAMP

  go=2 ph31

#ifdef ONE_D
  d11 wr #0 H2_LOCK
#else
  d11 wr #0 if #0 zd H2_LOCK
#endif
  d13 LOCKH_OFF
#ifdef N15_EVOL
  3m igrad EA
  d14 ip16
  d14 ip16
  lo to 3 times 2
  d14 dd10
  d14 id30
  d14 ip14
  d14 ip14
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd10
  d14 rd30
#endif
#ifdef CO_EVOL
  d14 ip13
  lo to 5 times 2
  d14 id0
  d14 ip31
  d14 ip31
  lo to 6 times l6
  d14 rd0
#endif
#ifdef CA_EVOL
  d14 ip11
  lo to 7 times 2
  d14 dd19
  d14 id20
  d14 id21
  d14 ip31
  d14 ip31
  lo to 8 times l8
#endif

  d14 LOCKDEC_OFF

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph10=0
ph11=0
ph12=0 1 2 3
ph13=0 0 2 2
ph14=1
ph15=0 0 2 2
ph16=0
ph19=1			; phase y on Bruker DMX
ph21=(360) 270		; phase ph19+180
ph31=0 2 2 0