;hncaf.fa
;3D HNCA with Watergate reverse INEPT (FHSQC) and optional 2H decoupling
;This version makes use of the gp gradient syntax.
;This version uses no ct evolution of Ca
;Yamazaki et al., J.Am. Chem. Soc. 1994, 116, 6464-6465
;Mori et al., J. Magn. Reson. B 108, 94-98 (1995)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hncaf.fa,v 1.4 2001/12/28 06:20:10 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C, f4: 2H (channel assignments may be changed below)
;o1p: 4.7ppm,
;o2p: 118ppm,
;o3p: 56ppm,
;o4p:: 4.5ppm
;
;d1: relaxation delay=d1+0.10s
;p1 90 H1 at pl1
;p11 90 2.0 ms H1 semi-selective H2O flip-back pulse at power:
;  1) pl21 (zgsel1.fa), with phcor21;
;  2) pl22 (zgsel2.fa), with phcor22.
;  Check for a possible phase difference between hard H1 and soft H1
;  pulses and set phcor21 and phcor22 accordingly.
;p10 90 H at pl10 (H1 composite decoupling)
;p2 90 N at pl2
;p3  90 dgr. Ca at pl3 for 90 dgr. rectangular semi-selective:
;   field strength=dNu/sqrt(15), dNu=(176ppm-54ppm)*bf3. p3 53.0 us at 600 MHz.
;p4 90 dgr. Ca at pl4 for 180 dgr. rectangular semi-selective:
;   field strength=dNu/sqrt(3), dNu=(176ppm-54ppm)*bf3. p4 23.7 us at 600 MHz.
;p25 90 2H pulse at pl15
;pl0 120dB
;d21: 1/(2*dNu), dNu=(ChSh(NH)-ChSh(H2O))*bf1, 300us at 500MHz
;
;H1  Waltz-16x or DIPSI-2x (cpdprg1), using p90 (PCPD1) at pl10
;N15 Waltz-16 (cpdprg2), using p90 (PCPD2) at pl12
;C'  Compensated SEDUCE1 decoupling of C', using pcpd3 at sp3,
;    shape seduce1c5/6, offset 0, cpdprg3 waltz16sp3. Select a pulse
;    length (PCPD3) that gives the right offset and adjust sp3 to make
;    PCPD3 a 90 dgr pulse.
;H2  Waltz-16 (cpdprg5), using p90 (PCPD) at pl15
;N15 evolution:
;  in10=in30, SW(N)=1/2*in10
;  l4 complex points; max. is (d10/in10)+1
;  Process as States (although data is acquired as States-TPPI)
;  N15 chemical shift axis is reversed: set reverse to true.
;C13 evolution:
;  in0, SW(C)=1/2*in0
;  l6 complex points
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F1.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;ns=8, 16, ..., ds=8, 16,...
;
;Recommendations for gradients, three axis (single axis):
;gpz1:  15% (15%)
;gpz2:   6% (6%)
;gpz3:  15% (15%)
;gpz4:  -8% (-8%)
;gpz5:  15% (15%)
;gpz6:  12% (12%)
;gpx7:  54%,adjust for magic-angle (0%)
;gpz7:  30% (55%)
;gpnam1: sine.100
;gpnam2: sine.50
;gpnam3: sine.100
;gpnam4: sine.100
;gpnam5: sine.50
;gpnam6: sine.50
;gpnam7: sine.100
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
#define N15_EVOL	; comment out for 2D w/o N15 evolution
#define C13_EVOL	; comment out for 2D w/o C13 evolution
;#define H2_DEC		; uncomment to enable H2 decoupling
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
#define D f4
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef N15_EVOL
#undef C13_EVOL
#endif
;
aqseq 321
;
define delay TAUA
define delay TAUA2
define delay TAUA7
define delay TAUB
define delay TAUC
define delay TAUC1
define delay TAUW
define delay TAUW1
define delay TN
define delay CEN_HN1
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse H1_90
define pulse H1_180
define pulse H1_S90
define pulse N15_90
define pulse N15_180
define pulse CA_90
define pulse CA_180
"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;a short delay
"d14=20u"			;ip,id etc.
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"H1_S90=p11"
"N15_90=p2"
"N15_180=N15_90*2"
"CA_90=p3"
"CA_180=p4*2"

"GRAD1=700u"
"GRAD2=500u"
"GRAD3=1.0m"
"GRAD4=1.0m"
"GRAD5=600u"
"GRAD6=500u"
"GRAD7=700u"

"d6=H1_90"
"TAUW=d21"
"TAUW1=(TAUW/2)-N15_90"
"TAUA=2.3m"
"TAUA2=TAUA-GRAD2-d13-d16"
"TAUA7=TAUA-TAUW*2.5-H1_90*2.385-GRAD7-d16-d13"
"TAUB=5.4m"
"TAUC=11.0m-CA_180"
"TAUC1=TAUC+CA_180-TAUB-p10-d13-d12"
"TN=12.4m"
"d10=TN-d13*2-d12"
"d30=TN-TAUB-CA_180-p10-d12*2-d13*5"
#ifdef C13_EVOL
 "d0=((cnst0*2+1)*in0-CA_90*1.273-N15_180-d12-d13*2)/2"
#endif
"CEN_HN1=N15_90-H1_90"


#define H1_DEC_ON d13 \n d12 pl10:H \n p10:H ph1 \n d13 cpds1:H

#define H1_DEC_OFF d13 do:H \n p10:H ph3 \n d13 \n d12 pl1:H

#define H1_DEC_OFF_Y d13 do:H \n p10:H ph1 \n d13 \n d12 pl1:H

#ifdef H2_DEC
#define H2_DEC_ON d12 pl15:D \n p25:D ph1 \n d13 cpds5:D
#define H2_DEC_OFF d13 do:D \n p25:D ph3
#else
#define H2_DEC_ON d13
#define H2_DEC_OFF d13
#endif

#define SED_ON d13 \n d12 pl0:C \n d13 cpds3:C

#define SED_OFF d13 do:C \n d12 pl4:C \n d13
#define SED_OFF3 d13 do:C \n d12 pl3:C \n d13

#ifdef EXPTCORR
  "d31=2*(TAUA2+GRAD2+TAUB+TAUA7+GRAD7+2*TAUW+TAUW1)+GRAD1+GRAD3+TAUC1+TAUC+GRAD4+GRAD5+GRAD6"
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d13 do:N
  d13 H2_LOCK
  d11 LOCKH_OFF
  d14
3 d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif  
  d1 pl1:H pl2:N
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  d13 H2_PULSE
  (N15_90 ph0):N
  d13
  GRAD1:gp1		;400u, 10G/cm
  d16
  (H1_90 ph0):H
  d13
  GRAD2:gp2		;500u, 4G/cm
  d16
  TAUA2
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  TAUA2
  d13
  GRAD2:gp2		;500u, 4G/cm
  d16
  (H1_90 ph1):H
  d13
  d12 pl22:H
  (H1_S90 ph22:r):H	;2ms 90 H1 pulse at phase x
  d13
  GRAD3:gp3		;1.0m, 10G/cm
  d16
  SED_ON
  (N15_90 ph11):N
  TAUB
  H1_DEC_ON
  TAUC1
  SED_OFF
  (N15_180 ph0):N
  d13
  (CA_180 ph0):C
  SED_ON
  TAUC
  (N15_90 ph0):N
  H1_DEC_OFF_Y
  SED_OFF3
  d13
  GRAD4:gp4		;1.0m, -5G/cm
  d16
  H2_DEC_ON
  (CA_90 ph12):C
#ifdef C13_EVOL
  SED_ON
  d0
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d0
  SED_OFF3
#else
  d13
  (H1_180 ph0):H
  d13
#endif
  (CA_90 ph0):C 
  H2_DEC_OFF
  d13
  GRAD5:gp5		;600u, 10G/cm
  d16
  SED_ON
  H1_DEC_ON
  (N15_90 ph13):N
  d10
  SED_OFF
  (N15_180 ph14):N
  d13
  (CA_180 ph0):C
  SED_ON
  d30
  H1_DEC_OFF
  TAUB
  (N15_90 ph0):N
  SED_OFF
  d13
  GRAD6:gp6		;500u, 8G/cm
  d16 pl21:H
  (H1_S90 ph21:r):H	;2ms 90 H1 pulse at phase x
  d13
  d12 pl1:H
  (H1_90 ph2):H
  d13
  TAUA7
  GRAD7:gp7		;700u, 40G/cm
  d16
  (H1_90*0.231 ph1):H
  TAUW
  (H1_90*0.692 ph1):H
  TAUW
  (H1_90*1.462 ph1):H
  TAUW1
  (N15_180 ph0):N
  TAUW1
  (H1_90*1.462 ph3):H
  TAUW
  (H1_90*0.692 ph3):H
  TAUW
  (H1_90*0.231 ph3):H
  d13
  GRAD7:gp7		;700u, 40G/cm
  d16 pl12:N
  TAUA7
  d6 BLKGRAMP
  go=2 ph31 cpds2:N

#ifdef ONE_D
  d11 do:N wr #0
#else
  d11 do:N wr #0 if #0 zd
#endif
  d13 H2_LOCK
  d13 LOCKH_OFF
#ifdef N15_EVOL
  d14 ip13
  lo to 3 times 2
  d14 dd10
  d14 id30
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd10
  d14 rd30
#else
  d14*7
#endif
#ifdef C13_EVOL
  d14 ip12
  lo to 5 times 2
  d14 id0 
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif
exit

ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 2
ph12=0 0 2 2
ph13=0
ph14=0 0 0 0 2 2 2 2
ph21=0
ph22=0
ph31=0 2 2 0