;hncatrkay.fa
;3D TROSY-HNCA
;Yang and Kay, J. Am. Chem. Soc. 1999, 121, 2571-2575.
;Bruker Avance/Xwin-nmr version. This program requires XWIN-NMR 2.5+
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hncatrkay.fa,v 1.4 2000/09/25 16:52:01 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C, f4: 2H (channel assignments may be changed below)
;o1p: 4.7 ppm
;o2p: 118 ppm,
;o3p: 58 ppm
;o4p: 4.5 ppm
;
;d1: relaxation delay = d1+0.1s
;p1 90 H at pl1
;p2 90 N at pl2
;p3  90 dgr. Ca at pl3 for 90 dgr. rectangular semi-selective:
;   field strength=dNu/sqrt(15), dNu=(176ppm-58ppm)*bf3. p3 54.4 us at 600 MHz. 
;p4 90 dgr. Ca at pl4 for 180 dgr. rectangular semi-selective:
;   field strength=dNu/sqrt(3),	dNu=(176ppm-58ppm)*bf3. p4 24.4 us at 600 MHz.
;p5 180 dgr. CO rectangular shaped (spnam5) at power sp5, offset CO-Ca,
;   semi-selective: field strength=dNu/sqrt(3),	dNu=(176ppm-58ppm)*bf3.
;   p5 48.8 us at 600 MHz.
;p11 90 H1 shaped (spnam1, EBURP-1) H2O pulse at power sp1, offset 0.
;   p11 ~ 7 ms. Check for a possible phase difference between hard H1 and
;   soft H1 pulses and set the phase program ph21 accordingly.
;p25 90 dgr. 2H pulse at pl15   
;pl0 120dB
;
;H2 Waltz-16 (cpdprg5) decoupling, 90 dgr. pulse (PCPD) at pl15
;N15 evolution:
;  in10=in30, SW(N)=1/(2*in10), typ. 30-40 ppm
;  l4 complex points; max. is (d10/in10)+1
;  Process as echo-antiecho.
;  Chemical shift axis is reversed.
;C13 evolution:
;  in0, SW(C)=1/(2*in0), typ. 15 ppm
;  l6 complex points.
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase error in F1.
;  cnst0=1 gives (270,-540) phase error in F1 (use LP to correct).
;ns=8, 16, ..., ds=8, 16,...
;
;Recommendations for gradients:
;gpz1:   7%
;gpy2:  30%
;gpy3: -44%
;gpz5:  15%
;gpx6:  54% adjust for magic angle
;gpz6:  30%
;gpx7:  44%
;gpy8:  30%
;gpx9:  54% adjust for magic angle
;gpz9:  30%
;gpnam1: sine.50
;gpnam2: sine.100
;gpnam3: sine.100
;gpnam5: sine.50
;gpnam6: sine.100
;gpnam7: sine.50
;gpnam8: sine.50
;gpnam9: sine.20
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
#define N15_EVOL	; comment out for 2D w/o N15 evolution
#define C13_EVOL		; comment out for 2D w/o C13 evolution
#define H2_DEC		; uncomment if 2H labeled sample
#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD9)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
#define D f5
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef N15_EVOL
#undef C13_EVOL
#endif
;
aqseq 321
;
define delay DELTA
define delay TAUA
define delay TAUA1
define delay TAUA7
define delay TAUA8
define delay TAUB
define delay TN
define delay TN2
define delay CEN_HN1
define delay CEN_CN1
define delay CEN_CN2
define pulse H1_90
define pulse H1_180
define pulse H1_S90
define pulse N15_90
define pulse N15_180
define pulse CA_90
define pulse CA_180
define pulse CO_180
define pulse CA_REBP
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD8
define pulse GRAD9

"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;just a short delay
"d14=60u"			;ip,id etc
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"H1_S90=p11"
"N15_90=p2"
"N15_180=N15_90*2"
"CA_90=p3"
"CA_180=p4*2"
"CO_180=p5"
;
"GRAD1=400u"
"GRAD2=1.0m"
"GRAD3=750u"
"GRAD5=500u"
"GRAD6=3.000m"
"GRAD7=400u"
"GRAD8=400u"
#ifndef OPTIM_P19
"p19=305u"			; configurable: set to the optimum value on your instrument
#endif
"GRAD9=p19"

"TAUA=2.2m"			; configurable: ~1/(4*JNH)
"TAUA1=TAUA-GRAD1-d16-d13"
"TAUA7=TAUA-GRAD7-d16-d13"
"TAUA8=TAUA-GRAD8-d16-d13"
"TAUB=12.0m"			; configurable: usually 12ms
"TN=12.0m"			; configurable: usually 12ms
"d10=TN"
"d30=d13"
"TN2=TN-d13-GRAD6-d16-CO_180-d30"
"DELTA=GRAD9+d16+d13*2"
"CEN_HN1=N15_90-H1_90"
"CEN_CN1=(N15_180-CA_180)/2"

#ifdef C13_EVOL
  "d0=((cnst0*2+1)*in0-CA_90*1.273-N15_180-d12*2-d13*2)/2"
  "CEN_CN2=(N15_180-CO_180)/2"
#endif

#ifdef EXPTCORR
  "d31=2*(TAUA1+TAUB+TAUA7+TAUA8+GRAD1+GRAD7+GRAD8)+GRAD2+GRAD3+GRAD5+GRAD6+TN2+DELTA+GRAD9"
#endif

#ifdef H2_DEC
#define H2_DEC_ON d12 pl15:D \n p25:D ph1 \n d13 cpds5:D
#define H2_DEC_OFF d13 do:D \n p25:D ph3
#else
#define H2_DEC_ON d13
#define H2_DEC_OFF d13
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
  d11 LOCKDEC_ON
2 d13
  d14 H2_LOCK
  d11 LOCKH_OFF
  3m
  d14
3 d14
  d14
  d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif  
  d1 pl1:H pl2:N
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  d13 H2_PULSE
; INEPT transfer from H to N
  (d13 d12 pl0 H1_S90:sp1 ph21 d13 d12 pl1):H	;Selective 90 H1 pulse phase -y
  (H1_90 ph0):H
  d13
  GRAD1:gp1		; 0.4ms, 5G/cm, z, sine.50
  d16
  TAUA1
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA1
  GRAD1:gp1		; 0.4ms, 5G/cm, z, sine.50
  d16
  (H1_90 ph19):H	; phase y on Bruker DMX
  d13
  GRAD2:gp2		; 1.0ms, 10G/cm, z, sine.100
  d16 
; INEPT transfer from N to Ca
  (N15_90 ph10):N
  TAUB pl4:C
  (CEN_CN1 CA_180 ph0):C (N15_180 ph0):N
  TAUB
  (N15_90 ph1):N
  d13
  GRAD3:gp3		; 700us, 10G/cm, z, sine.100
  d16 pl3:C
  H2_DEC_ON
; Begin Ca evolution
  (CA_90 ph11):C
#ifdef C13_EVOL
  (d13 d12 pl0):C
  d0
  (CEN_CN2 CO_180:sp5 ph0):C (N15_180 ph0):N
  d0
  (d13 d12 pl3):C
#else
   d13
#endif
  (CA_90 ph0):C
; End Ca evolution
  H2_DEC_OFF
  GRAD5:gp5		; 0.5ms, 10G/cm, z, sine.50
  d16 pl4:C
; Begin constant time evolution on N
  (N15_90 ph12):N
  d10
  (N15_180 ph13 TN2):N (CEN_CN1 CA_180 ph0):C
  d13
  GRAD6:gp6*EA*-1	; 3.000 ms, -/+30G/cm, ma, sine.100
  d16 pl0:C
  (CO_180:sp5 ph0):C
  d30
; End constant time
; Sensitivity enhanced coherence transfer from N to H
  (N15_90 ph14):N
  (H1_90 ph0):H
  d13
  GRAD7:gp7		; 0.4ms, 3.1G/cm, z, sine.50
  d16
  TAUA7
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA7
  GRAD7:gp7		; 0.4ms, 3.1G/cm, z, sine.50
  d16
  (H1_90 ph1):H
  d13
  (N15_90 ph1):N
  d13
  GRAD8:gp8		; 0.4ms, 5.35G/cm, z, sine.50
  TAUA8
  d16
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA8
  GRAD8:gp8		; 0.4ms, 5.35G/cm, z, sine.50
  d16
  (N15_90 ph0):N
  d13
  (H1_90 ph0):H
  DELTA
  (H1_180 ph0):H
  d13
  GRAD9:gp9		; 305u, 30G/cm, ma, sine.20
  d13
  d16 BLKGRAMP

  go=2 ph31

#ifdef ONE_D
  d11 wr #0 H2_LOCK
#else
  d11 wr #0 if #0 zd H2_LOCK
#endif
  d13 LOCKH_OFF
#ifdef N15_EVOL
  3m igrad EA
  d14 ip14
  d14 ip14
  lo to 3 times 2
  d14 dd10
  d14 id30
  d14 ip12
  d14 ip12
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd10
  d14 rd30
#else
  d14*10
  3m
#endif
#ifdef C13_EVOL
  d14 ip11
  lo to 5 times 2
  d14 id0
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif
  d14 LOCKDEC_OFF

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph10=0
ph11=0 0 2 2
ph12=1 3
ph13=0 0 0 0 2 2 2 2
ph14=0
ph19=1			; phase y on Bruker DMX
ph21=(360) 270		; phase ph19+180
ph31=0 2 2 0