;hncocacbtr.fa
;3D TROSY-HN(CO)CACB
;Yang and Kay, J. Am. Chem. Soc. 1999, 121, 2571-2575.
;Bruker Avance/Xwin-nmr version. This program requires XWIN-NMR 2.5+
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hncocacbtr.fa,v 1.2 2001/08/25 03:45:16 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C, f4: 2H (channel assignments may be changed below)
;o1p: 4.7 ppm
;o2p: 118 ppm,
;o3p: use fq3list fahncocacbtr.C (176 ppm, 43 ppm, 176 ppm)
;o4p: 4.5 ppm
;
;d1: relaxation delay = d1+0.1s
;p1 90 H at pl1
;p2 90 N at pl2
;p3  90 dgr. CO at pl3 for 90 dgr. rectangular semi-selective:
;   field strength=dNu/sqrt(15), dNu=(176ppm-55ppm)*bf3. p3 54.4 us at 600 MHz. 
;p4 90 dgr. CO at pl4 for 180 dgr. rectangular semi-selective:
;   field strength=dNu/sqrt(3),	dNu=(176ppm-55ppm)*bf3. p4 24.4 us at 600 MHz.
;p5 180 dgr. Ca rectangular shaped (spnam5) at power sp5, offset Ca-CO,
;   semi-selective: field strength=dNu/sqrt(3),	dNu=(176ppm-55ppm)*bf3.
;   p5 48.8 us at 600 MHz.
;p6  90 dgr. Cab at pl6 for 90 dgr. rectangular semi-selective:
;   field strength=dNu/sqrt(15), dNu=(176ppm-43ppm)*bf3. 
;p8 180 dgr. shaped Cab refocusing REBURP (spnam8) pulse (non-selective for
;   aliphatic). Centered at 43 ppm (offset 0). p8 ~350us at 600 MHz.
;   Adjust phase program ph22 for max. intensity.
;p9 180 dgr. shaped CO/Cg G3 (spnam9) pulse at power sp9, offset 150-43 ppm.
;   p9 300 us at 600 MHz.
;p11 90 H1 shaped (spnam1, EBURP-1) H2O pulse at power sp1, offset 0.
;   p11 ~ 7 ms. Check for a possible phase difference between hard H1 and
;   soft H1 pulses and set the phase program ph21 accordingly.
;   Use zgsel5.fa to calibrate.
;p25 90 dgr. 2H pulse at pl15   
;pl0 120dB
;
;H2 Waltz-16 (cpdprg5) decoupling, 90 dgr. pulse (PCPD) at pl15
;N15 evolution:
;  in10=in30, SW(N)=1/(2*in10), typ. 30-40 ppm
;  l4 complex points; max. is (d10/in10)+1
;  Process as echo-antiecho.
;  Chemical shift axis is reversed.
;C13 evolution:
;  SW(C)=1/(2*in0), typ. 55 ppm
;  l6 complex points.
;  set cnst0 to 0 (preferably) or 1, 2, 3 .. to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F1.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  Chemical shift axis is reversed.
;ns=8, 16, ..., ds=8, 16,...
;
;Recommendations for gradients, triple-axis (single-axis):
;gpz1:   7%
;gpz2:  15%
;gpz3:  15%
;gpz4:  22%
;gpz5:  22%
;gpz6:  29%
;gpz8:  37%
;gpz9:  18%
;gpz10:  18%
;gpz11: 22%
;gpx12: 54% adjust for magic angle (0%)
;gpz12: 30% (55%)
;gpx13:  5% (0%)
;gpz13:  0% (5%)
;gpy14:  8% (0%)
;gpz14:  0% (8%)
;gpx15: 54% adjust for magic angle (0%)
;gpz15: 30% (55%)
;gpnam1: sine.50
;gpnam2: sine.100
;gpnam3: sine.100
;gpnam4: sine.20
;gpnam5: sine.50
;gpnam6: sine.10
;gpnam8: sine.10
;gpnam9: sine.50
;gpnam10: sine.20
;gpnam11: sine.50
;gpnam12: sine.100
;gpnam13: sine.50
;gpnam14: sine.50
;gpnam15: sine.20
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
#define N15_EVOL	; comment out for 2D w/o N15 evolution
#define C13_EVOL	; comment out for 2D w/o C13 evolution
#define H2_DEC		; uncomment if 2H labeled sample
;#define CACB		; uncomment for both Ca and Cb peaks, otherwise Cb only
;#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD11)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
#define D f5
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef N15_EVOL
#undef C13_EVOL
#endif
#ifndef C13_EVOL
#undef CACB
#endif
;
aqseq 321
;
define delay DELTA
define delay TAUA
define delay TAUA1
define delay TAUA13
define delay TAUA14
define delay TAUB
define delay TAUC
define delay TAUC4
define delay TAUC10
define delay TAUD
define delay TAUD6
define delay TAUD8
define delay TN
define delay TN2
define delay CEN_HN1
define pulse H1_90
define pulse H1_180
define pulse H1_S90
define pulse N15_90
define pulse N15_180
define pulse CO_90
define pulse CO_180
define pulse CAB_90
define pulse CAO_180
define pulse CA_REBP
define pulse CO_G3
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD8
define pulse GRAD9
define pulse GRAD10
define pulse GRAD11
define pulse GRAD12
define pulse GRAD13
define pulse GRAD14
define pulse GRAD15

"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;just a short delay
"d14=60u"			;ip,id etc
"d16=300u"			;gradient recovery
"d17=50u"			;short gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"H1_S90=p11"
"N15_90=p2"
"N15_180=N15_90*2"
"CO_90=p3"
"CO_180=p4*2"
"CAO_180=p5"
"CAB_90=p6"
"CA_REBP=p8"
"CO_G3=p9"
;
"GRAD1=400u"
"GRAD2=1.0m"
"GRAD3=700u"
"GRAD4=200u"
"GRAD5=600u"
"GRAD6=80u"
"GRAD8=80u"
"GRAD9=500u"
"GRAD10=200u"
"GRAD11=500u"
"GRAD12=3.000m"
"GRAD13=400u"
"GRAD14=400u"
#ifndef OPTIM_P19
"p19=305u"			; configurable: set to the optimum value on your instrument
#endif
"GRAD15=p19"

"TAUA=2.3m"			; configurable: ~1/(4*JNH)
"TAUB=12.0m"			; configurable: usually 12ms
"TAUC=4.0m"
#ifdef CACB
  "TAUD=3.5m"			; 3.5 ms for Ca and Cb
#else
  "TAUD=6.8m"			; 6.8-7.1ms for Cb only,
#endif
"TAUA1=TAUA-GRAD1-d16-d13"
"TAUA13=TAUA-GRAD13-d16-d13"
"TAUA14=TAUA-GRAD14-d16-d13"
"TAUC4=TAUC-GRAD4-d16-d13"
"TAUC10=TAUC-GRAD10-d16-d13"
#ifdef H2_DEC
  "TAUD6=TAUD-GRAD6-d17-p25-d12-d13*2"
  "TAUD8=TAUD-GRAD8-d17-p25-d12-d13*2"
#else
  "TAUD6=TAUD-GRAD6-d17-d13*2"
  "TAUD8=TAUD-GRAD8-d17-d13*2"
#endif
"TN=12.0m"			; configurable: usually 12ms
"d10=TN"
"d30=d13"
"TN2=TN-d13-GRAD12-d16-CAO_180-d13"
"DELTA=GRAD15+d16+d13*2"
"CEN_HN1=N15_90-H1_90"

#ifdef C13_EVOL
  "d0=((cnst0*2+1)*in0-CAB_90*1.273-CO_G3-d12*2-d13*2)/2"
#endif

#ifdef EXPTCORR
  "d31=2*(GRAD1+TAUA1+TAUB+GRAD4+TAUC4+GRAD6+TAUD6+GRAD8+TAUD8+GRAD10+TAUC10+TAUA13+GRAD13+TAUA14+GRAD14)+GRAD2+GRAD3+GRAD5+GRAD9+GRAD11+TN2+GRAD12+DELTA+GRAD15"
#endif

#ifdef H2_DEC
#define H2_DEC_ON d12 pl15:D \n p25:D ph1 \n d13 cpds5:D
#define H2_DEC_OFF d13 do:D \n p25:D ph3 d12
#else
#define H2_DEC_ON d13
#define H2_DEC_OFF d13
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
  d11 LOCKDEC_ON
2 d13
  d14 H2_LOCK
  d11 LOCKH_OFF
  3m
  d14
3 d14
  d14
  d14
  d14
  d14
  d14
4 d14
  d14
  d14
  d14
5 d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif  
  d1 pl1:H pl2:N
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  d13 H2_PULSE
  d14 fq3:C		; C13 at 176 ppm
; INEPT transfer from H to N
  (d13 d12 pl0 H1_S90:sp1 ph21 d13 d12 pl1):H	;Selective 90 H1 pulse phase -y
  (H1_90 ph0):H
  d13
  GRAD1:gp1		; 0.4ms, 5G/cm, z, sine.50
  d16
  TAUA1
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA1
  GRAD1:gp1		; 0.4ms, 5G/cm, z, sine.50
  d16
  (H1_90 ph19):H	; phase y on Bruker DMX
  d13
  GRAD2:gp2		; 1.0ms, 10G/cm, z, sine.100
  d16 
; INEPT transfer from N to CO
  (N15_90 ph10):N
  TAUB pl4:C
  (N15_180 ph0):N
  (TAUB) (d13 CO_180 ph0):C
  (N15_90 ph1):N
  d13
  GRAD3:gp3		; 700us, 10G/cm, z, sine.100
  d16 pl3:C
; INEPT transfer from CO to Ca.
  (CO_90 ph11):C
  (TAUC4) (d13 d12 pl0 CAO_180:sp5 ph0 d13 d12 pl4):C
  d13
  GRAD4:gp4		; 200us, 15G/cm, z, sine.20
  d16
  (CO_180 ph0):C
  (d16) (d13 d12 pl0 CAO_180:sp5 ph0 d13 d12 pl3):C
  d13
  GRAD4:gp4		; 200us, 15G/cm, z, sine.20
  TAUC4
  (CO_90 ph1):C
  d13
  GRAD5:gp5*-1		; 600us, -15G/cm, z, sine.50
  d16 fq3:C		; C13 at 43 ppm
  d13
  d12 pl6:C
  H2_DEC_ON
; Ca-Cb transfer
  (CAB_90 ph12):C
  TAUD6
  H2_DEC_OFF
  d13
  GRAD6:gp6		; 80us, 20G/cm, z, sine.10
  d17 pl0:C
  (CA_REBP:sp8 ph22):C  ; adjust ph22 for max. signal
  d13
  GRAD6:gp6		; 80us, 20G/cm, z, sine.10
  d17
  H2_DEC_ON
  TAUD6 pl6:C
  (CAB_90 ph13):C
; Begin C13 evolution
#ifdef C13_EVOL
  (d13 d12 pl0):C
  d0
  (CO_G3:sp9 ph0):C
  d0
  (d13 d12 pl6):C
#else
   d13
#endif
; End C13 evolution  
  (CAB_90 ph1):C
; Ca-Cb back-transfer
  TAUD8
  H2_DEC_OFF
  d13
  GRAD8:gp8		; 80us, 25G/cm, x, sine.10
  d17 pl0:C
  (CA_REBP:sp8 ph22):C  ; adjust ph22 for max. signal
  d13
  GRAD8:gp8		; 80us, 25G/cm, x, sine.10
  d17
  H2_DEC_ON
  TAUD8 pl6:C
  (CAB_90 ph0):C
  H2_DEC_OFF
  d13
  GRAD9:gp9		; 0.5ms, 12G/cm, z, sine.50
  d16 fq3:C		; C13 at 176 ppm 
  d13
  d12 pl3:C
; Ca-CO back-transfer
  (CO_90 ph1):C
  (TAUC10) (d13 d12 pl0 CAO_180:sp5 ph0 d13 d12 pl4):C
  d13
  GRAD10:gp10		; 200us, 12G/cm, z, sine.20
  d16
  (CO_180 ph0):C
  (d16) (d13 d12 pl0 CAO_180:sp5 ph0 d13 d12 pl3):C
  d13
  GRAD10:gp10		; 200us, 12G/cm, z, sine.20
  TAUC10
  (CO_90 ph0):C
  d13
  GRAD11:gp11		; 0.5ms, 15G/cm, z, sine.50
  d16 pl4:C
; Begin constant time evolution on N (t3)
  (N15_90 ph14):N
  d10
  (N15_180 ph15):N
  (TN2) (d13 CO_180 ph0):C
  d13
  GRAD12:gp12*EA*-1	; 3.000 ms, -/+30G/cm, ma, sine.100
  d16 pl0:C
  (CAO_180:sp5 ph0):C
  d30
; End constant time
; Sensitivity enhanced coherence transfer from N to H
  (N15_90 ph16):N
  (H1_90 ph0):H
  d13
  GRAD13:gp13		; 0.4ms, 3.1G/cm, z, sine.50
  d16
  TAUA13
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA13
  GRAD13:gp13		; 0.4ms, 3.1G/cm, z, sine.50
  d16
  (H1_90 ph1):H
  d13
  (N15_90 ph1):N
  d13
  GRAD14:gp14		; 0.4ms, 5.35G/cm, z, sine.50
  TAUA14
  d16
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA14
  GRAD14:gp14		; 0.4ms, 5.35G/cm, z, sine.50
  d16
  (N15_90 ph0):N
  d13
  (H1_90 ph0):H
  DELTA
  (H1_180 ph0):H
  d13
  GRAD15:gp15		; 305 us, 30G/cm, ma, sine.20
  d13
  d16 BLKGRAMP

  go=2 ph31

#ifdef ONE_D
  d11 wr #0 H2_LOCK
#else
  d11 wr #0 if #0 zd H2_LOCK
#endif
  d13 LOCKH_OFF
#ifdef N15_EVOL
  3m igrad EA
  d14 ip16
  d14 ip16
  lo to 3 times 2
  d14 dd10
  d14 id30
  d14 ip14
  d14 ip14
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd10
  d14 rd30
#else
  d14*10
  3m
#endif
#ifdef C13_EVOL
  d14 ip12
  d14 ip13
  lo to 5 times 2
  d14 id0
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif
  d14 LOCKDEC_OFF

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph10=0
ph11=0 2
ph12=0 0 2 2
ph13={1}*4 {3}*4
ph14=1
ph15={0}*4 {2}*4
ph16=0
ph19=1			; phase y on Bruker DMX
ph21=(360) 270		; phase ph19+180
ph22=(360) 0		; phase x plus any phase diff.
ph31=0 2 2 0