;hncof.fa
;3D HNCO - with Watergate reverse INEPT (FHSQC) and minimal H2O saturation.
;This version makes use of the gp gradient syntax.
;Kay, Xu, and Ymazaki, J. Magn. Reson. A 10l, 129-133 (1994)
;Mori et al., J. Magn. Reson. B 108, 94-98 (1995)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hncof.fa,v 1.7 2001/11/29 18:24:29 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm,
;o3p: use fq3list fahncof.C (175ppm,56ppm)
;
;d1: relaxation delay = d1+0.1s
;p1 90 H at pl1
;p11 H1 2ms selective water flip-back pulse at power pl11. 
; Check for phase difference between hard H1 and soft H1 
; pulses and set phcor21 accordingly.
;p10 90 H at pl10 (H1 composite decoupling)
;p2 90 N at pl2. If p5/2 > p2 define SHORT_P2 below.
;p3 90 CO at pl3 
;   semi-selective: p90=sqrt(15)/(4*dNu), dNu=(175ppm-55ppm)*bf3); 64.4us at 500MHz
;p5 180 Ca square shaped (spnam5) at power sp5, offset Ca-CO (-120ppm)
;   semi-selective: p180=sqrt(3)/(2*dNu), dNu=(175ppm-55ppm)*bf3); 57.6us at 500MHz
;p8 180 CO square shaped (spnam8) at power sp8, offset CO-Ca (120ppm)
;   semi-selective: p180=sqrt(15)/(2*dNu), dNu=(175ppm-55ppm)*bf3); 128.8us at 500MHz
;pl0 120dB
;d21: 1/(2*dNu), dNu=(ChSh(NH)-ChSh(H2O))*bf1, 300us at 500MHz
;
;H1  Waltz-16x or DIPSI-2x (cpdprg1), using p90 (PCPD) at pl10
;N15 Waltz-16 (cpdprg2), 90 dgr pulse (PCPD) at pl12
;Ca  on-resonance SEDUCE1 decoupling of Ca, using p90 (PCPD) at sp3,
;    shape seduce1, offset 0, cpdprg3 waltz16sp3.
;N15 evolution:
;  in10=in30, SW(N)=1/(2*in10), typ. 35-40 ppm
;  l4 complex points; max. is (d10/in10)+1
;  N15 chemical shift axis has reverse orientation
;C13 evolution:
;  in0, SW(C)=1/(2*in0), typ. 15 ppm
;  l6 complex points
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F1.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  C' chemical shift axis is OK
;ns=8, 16, ..., ds=8, 16,...
;
;Recommendations for triple-axis (single-axis) gradients:
;gpz1:  15% (15%)
;gpz2:   6% (6%)
;gpz3:  15% (15%)
;gpz4:  -8% (-8%)
;gpz5:  15% (15%)
;gpz6:  12% (12%)
;gpx7:  54%, adjust for magic-angle (0%)
;gpz7:  30% (55%)
;gpnam1: sine.100
;gpnam2: sine.50
;gpnam3: sine.100
;gpnam4: sine.100
;gpnam5: sine.50
;gpnam6: sine.50
;gpnam7: sine.100
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
#define ONE_D		; uncomment for 1D experiment
#define N15_EVOL	; comment out for 2D w/o N15 evolution
#define CO_EVOL		; comment out for 2D w/o C13 evolution
;#define SHORT_P2	; uncomment if p5/2 > p2
#define CRP		; uncomment for use on CryoProbe (no sim. N15,C13 pulses)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef N15_EVOL
#undef CO_EVOL
#endif
;
;
define delay TAUA
define delay TAUA2
define delay TAUA7
define delay TAUB
define delay TAUC
define delay TAUW
define delay TAUW1
define delay CEN_HN1
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse H1_90
define pulse H1_180
define pulse H1_S90
define pulse N15_90
define pulse N15_180
define pulse CA_180
define pulse CO_90
define pulse CO_180
define pulse CAO_180
define pulse COA_180
"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;just a short delay
"d14=40u"			;ip,id etc
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"H1_S90=p11"
"N15_90=p2"
"N15_180=N15_90*2"
"CO_90=p3"
"CO_180=CO_90*2"
"CAO_180=p5"
"COA_180=p8"

"GRAD1=700u"
"GRAD2=500u"
"GRAD3=1.0m"
"GRAD4=1.0m"
"GRAD5=600u"
"GRAD6=500u"
"GRAD7=700u"

"d6=H1_90"
"TAUW=d21"
"TAUW1=(TAUW/2)-N15_90"
"TAUA=2.3m"
"TAUA2=TAUA-GRAD2-d13-d16"
"TAUA7=TAUA-TAUW*2.5-H1_90*2.385-GRAD7-d16-d13"
"TAUB=5.4m"
"TAUC=12.4m"
"d24=TAUC-TAUB-p10-d13*2-d12"
"d10=12.4m"
"d30=12.4m-TAUB-COA_180-p10-d12*3-d13*5"

#ifdef CO_EVOL
#ifdef CRP
 "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-N15_180-d12*2-d13*2)/2"
#else
#ifdef SHORT_P2
 "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-d12*2-d13*2)/2"
#else
 "d0=((cnst0*2+1)*in0-CO_90*1.273-N15_180-d12*2-d13*2)/2"
#endif
#endif
#endif

"CEN_HN1=N15_90-H1_90"

#define SED_ON d13 \n d12 pl0:C \n d13 cpds3:C

#define SED_OFF d13 do:C

#define H1_DEC_ON d13 \n d12 pl10:H \n p10:H ph1 \n d13 cpds1:H

#define H1_DEC_OFF d13 do:H \n p10:H ph3 \n d13 \n d12 pl1:H

#ifdef EXPTCORR
  "d31=2*(TAUA2+GRAD2+TAUB+TAUA7+GRAD7+2*TAUW+TAUW1)+GRAD1+GRAD3+TAUC+GRAD4+GRAD5+GRAD6"
#endif


#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d13 do:N
  d11 LOCKH_OFF
  d14
3 d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d14
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif  
  d1 pl1:H pl2:N
;-------------------- set carbon freq. on CO ---------------
  50u fq3:C
  d13 LOCKH_ON
  d13 UNBLKGRAMP
  (N15_90 ph0):N
  d13
  GRAD1:gp1		;400u, 10G/cm
  d16 pl3:C
;--------------------- INEPT to N --------------------------
  (H1_90 ph0):H
  d13
  GRAD2:gp2		;500u, 4G/cm
  d16
  TAUA2
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  TAUA2
  d13
  GRAD2:gp2		;500u, 4G/cm
  d16
  (H1_90 ph1):H
  d13
  d12 pl11:H
  (H1_S90 ph21:r):H        ;2ms 90 H1 pulse at phase x
  d13
  GRAD3:gp3		;1.0m, 10G/cm
  d16
;----------------- INEPT to C' and refocus H ---------------
  (N15_90 ph11):N
  TAUB
  H1_DEC_ON
  d24
  (N15_180 ph0):N
  (TAUC) (d13 CO_180 ph0):C
  (N15_90 ph0):N
  H1_DEC_OFF
  d13
  GRAD4:gp4		;1.0m, -5G/cm
  d16
;----------------------- C' evolution ------------------------
  (CO_90 ph12):C
  d13
#ifdef CO_EVOL
  d12 pl0:C
#ifdef CRP
  (d0 CAO_180:sp5 ph0):C
  (d13 N15_180 ph0 d0):N
  d12 pl3:C
#else
  (d0 CAO_180:sp5 ph0 d0):C (d0 N15_180 ph0 d0):N
  d13
  d12 pl3:C
#endif
#endif
  (CO_90 ph0):C
  d13
  GRAD5:gp5		;600u, 10G/cm
;--------------------- Switch C frequency to Ca --------------
  d16 fq3:C
  d12 pl0:C
  H1_DEC_ON 
  SED_ON
;------ Refocus C' and constant time evolution on N (t2) -----
  (N15_90 ph14):N
  d10
  (N15_180 ph15):N
  SED_OFF
  d12 pl0:C
  (COA_180:sp8 ph0):C
  SED_ON
  d30
  H1_DEC_OFF
  TAUB
  (N15_90 ph0):N
  SED_OFF
  d13
  GRAD6:gp6		;500u, 8G/cm
  d16 pl11:H
  (H1_S90 ph21:r):H        ;2ms 90 H1 pulse at phase x
  d13
  d12 pl1:H
  (H1_90 ph2):H
  d13
  TAUA7
  GRAD7:gp7		;700u, 40G/cm
  d16
  (H1_90*0.231 ph1):H
  TAUW
  (H1_90*0.692 ph1):H
  TAUW
  (H1_90*1.462 ph1):H
  TAUW1
  (N15_180 ph0):N
  TAUW1
  (H1_90*1.462 ph3):H
  TAUW
  (H1_90*0.692 ph3):H
  TAUW
  (H1_90*0.231 ph3):H
  d13
  GRAD7:gp7		;700u, 40G/cm
  d16 pl12:N
  TAUA7
  d6 BLKGRAMP
  go=2 ph31 cpds2:N

#ifdef ONE_D
  d11 do:N wr #0
#else
  d11 do:N wr #0 if #0 zd
#endif
  d13 LOCKH_OFF
#ifdef N15_EVOL
  d14 ip14
  lo to 3 times 2
  d14 dd10
  d14 id30
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd10
  d14 rd30
#else
  d14*7
#endif
#ifdef CO_EVOL
  d14 ip12
  lo to 5 times 2
  d14 id0 
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 2
ph12=0 0 0 0 2 2 2 2
ph14=0
ph15=0 0 2 2
ph16=0
ph21=0
ph31=0 2 0 2 2 0 2 0