;hncotrk2b.fa
;3D TROSY-HNCO
;Yang and Kay, J. Biomol. NMR. 13, 3-10 (1999) (experiment 2b in this paper)
;with modifications from Yang and Kay, J. Biomol. NMR. 14, 273-276 (1999).
;Bruker Avance/Xwin-nmr version. This program requires XWIN-NMR 2.5+
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: hncotrk2b.fa,v 1.4 2001/07/04 19:59:07 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm,
;o3p: 175ppm
;
;d1: relaxation delay = d1+0.1s
;p1 90 H at pl1
;p2 90 N at pl2. If p5/2 > p2 define SHORT_P2 below.
;p3  90 dgr. CO at pl3: B1=dNu/sqrt(15) (dNu=(175ppm-56ppm)*bf3) 
;p5 180 dgr. Ca square shaped (spnam5) at power sp5, offset Ca-CO (-119ppm)
;   semi-selective: field strength=dNu/sqrt(3), dNu=(175ppm-56ppm)*bf3)
;p11 (if SHAPED defined)
;   90 H1 shaped (spnam1, EBURP-1) H2O pulse at power sp1, offset 0.
;   p11 ~ 7 ms. Check for a possible phase difference between hard H1 and
;   soft H1 pulses and set the phase program ph21 accordingly.
;   Use zgsel5.fa to calibrate.
;p11 (if SHAPED not defined)
;   90 H1 2ms selective water flip-back pulse at power pl11. 
;   Check for phase difference between hard H1 and soft H1 
;   pulses and set phcor21 accordingly.
;   Use zgsel1.fa to calibrate.
;pl0 120dB
;
;N15 evolution:
;  in10=in30, SW(N)=1/(2*in10), typ. 30-40 ppm
;  l4 complex points; max. is (d30/in30)+1
;  Process as echo-antiecho.
;  Chemical shift axis is reversed.
;C13 evolution:
;  in0, SW(C)=1/(2*in0), typ. 15 ppm
;  l6 complex points
;  Quadrature detection by States-TPPI method.
;  set cnst0 to 0 (preferably) or 1 to make d0 the smallest possible
;  positive delay. cnst0=0 gives (90,-180) phase distortion in F1.
;  cnst0=1 gives (270,-540) phase distortion in F1 (use LP to correct).
;  Chemical shift axis is ok.
;ns=8, 16, ..., ds=8, 16,...
;
;Recommendations for triple-axis (single-axis) gradients:
;gpz1:   7%
;gpy2:  44% (0%)
;gpz2:   0% (44%)
;gpz3:  15%
;gpy4: -44% (0%)
;gpz4:   0% (-44%)
;gpx5:  54% adjust for magic angle (0%)
;gpz5:  30% (55%)
;gpx6:  44% (0%)
;gpz6:   0% (44%)
;gpy7:  44% (0%)
;gpz7:   0% (44%)
;gpx8:  54% adjust for magic angle (0%)
;gpz8:  30% (55%)
;gpnam1: sine.50
;gpnam2: sine.100
;gpnam3: sine.100
;gpnam4: sine.50
;gpnam5: sine.100
;gpnam6: sine.100
;gpnam7: sine.100
;gpnam8: sine.20
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
#define ONE_D		; uncomment for 1D experiment
#define N15_EVOL	; comment out for 2D w/o N15 evolution
#define CO_EVOL		; comment out for 2D w/o C13 evolution
;#define SHAPED		; uncomment if using a shaped flip-back pulse
;#define SHORT_P2	; uncomment if p5/2 > p2
#define CRP		; uncomment for use on CryoProbe (no sim. N15,C13 pulses)
;#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD8)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
;
;You shouldn't have to worry about anything beyond this point :-)
;
;sanity checks
;
#ifdef ONE_D
#undef N15_EVOL
#undef CO_EVOL
#endif
;
;
define delay DELTA
define delay TAUA
define delay TAUA1
define delay TAUA6
define delay TAUA7
define delay TN
define delay TN2
define delay CEN_HN1
define pulse H1_90
define pulse H1_180
define pulse H1_S90
define pulse N15_90
define pulse N15_180
define pulse CAO_180
define pulse CO_90
define pulse CO_180
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7
define pulse GRAD8

"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;just a short delay
"d14=60u"			;ip,id etc
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"H1_S90=p11"
"N15_90=p2"
"N15_180=N15_90*2"
"CAO_180=p5"
"CO_90=p3"
"CO_180=p3*2"
;
"GRAD1=500u"
"GRAD2=1.0m"
"GRAD3=750u"
"GRAD4=1.300m"
"GRAD5=2.700m"
"GRAD6=1.0m"
"GRAD7=1.0m"
#ifndef OPTIM_P19
"p19=274.5u"			; configurable: set to the optimum value on your instrument
#endif
"GRAD8=p19"

"TAUA=2.3m"			; configurable: ~1/(4*JNH)
"TAUA1=TAUA-GRAD1-d16-d13"
"TAUA6=TAUA-GRAD6-d16-d13"
"TAUA7=TAUA-GRAD7-d16-d13"
"TN=12.4m"			; configurable: usually 12-12.4ms
"d10=TN"
"d30=d13"
"TN2=TN-d13-GRAD5-d16-CAO_180-d30"
"DELTA=GRAD8+d16+d13*2"
"CEN_HN1=N15_90-H1_90"

#ifdef CO_EVOL
#ifdef CRP
 "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-N15_180-d12*2-d13*2)/2"
#else
#ifdef SHORT_P2
 "d0=((cnst0*2+1)*in0-CO_90*1.273-CAO_180-d12*2-d13*2)/2"
#else
 "d0=((cnst0*2+1)*in0-CO_90*1.273-N15_180-d12*2-d13*2)/2"
#endif
#endif
#endif


#ifdef EXPTCORR
  "d31=2*(TAUA1+TAUA6+TAUA7+TN+GRAD1+GRAD6+GRAD7)+GRAD2+GRAD3+GRAD4+GRAD5+GRAD8+DELTA+TN2"
#endif


#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d11 LOCKH_OFF
  d13
  3m
  d14
  d14
3 d14
  d14
  d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif  
  d1 pl1:H pl2:N
; INEPT transfer from H to N
  d13 LOCKH_ON
  d13 UNBLKGRAMP
#ifdef SHAPED
  (d13 d12 pl0 H1_S90:sp1 ph21 d13 d12 pl1):H	;Selective 90 H1 pulse phase -y
#else
  (d13 d12 pl11 H1_S90 ph21 d13 d12 pl1):H	;Selective 90 H1 pulse phase -y
#endif
  (H1_90 ph0):H
  d13
  GRAD1:gp1		; 0.5ms, 5G/cm, z, sine.50
  d16
  TAUA1
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA1
  GRAD1:gp1		; 0.5ms, 5G/cm, z, sine.50
  d16
  (H1_90 ph19):H	; phase y on Bruker DMX
  d13
  GRAD2:gp2		; 1.0ms, 15G/cm, z, sine.100
  d16 
; INEPT transfer from N to C'
  (N15_90 ph0):N
  TN pl3:C
  (N15_180 ph0):N
  (TN) (d13 CO_180 ph0):C
  (N15_90 ph1):N
  d13
  GRAD3:gp3		; 750us, 10G/cm, z, sine.100
  d16
; Begin C' evolution
  (CO_90 ph11):C
  d13
#ifdef CO_EVOL
  d12 pl0:C
#ifdef CRP
  (d0 CAO_180:sp5 ph0):C
  (d13 N15_180 ph0 d0):N
  d12 pl3:C
#else
  (d0 CAO_180:sp5 ph0 d0):C (d0 N15_180 ph0 d0):N
  d13
  d12 pl3:C
#endif
#endif
  (CO_90 ph0):C
; End C' evolution  
  d13
  GRAD4:gp4			; 1.3ms, 30G/cm, -y, sine.100
  d16
; Here starts panel "b" (Figure 2)
; Begin constant time evolution on N
  (N15_90 ph12):N
  d10
  (N15_180 ph13):N
  (TN2) (d13 CO_180 ph0):C
  d13
  GRAD5:gp5*EA*-1		; 2.700ms, +/-30G/cm, ma, sine.100
  d16 pl0:C
  (CAO_180:sp5 ph0):C
  d30
; End constant time
; Sensitivity enhanced coherence transfer from N to H
  (N15_90 ph14):N
  (H1_90 ph0):H
  d13
  GRAD6:gp6			; 1.0ms, 30G/cm, z, sine.100
  (TAUA6)
; Purge CO
  (d16) (d12 pl3 d13 CO_90 ph0):C
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA6
  GRAD6:gp6			; 1.0ms, 30G/cm, z, sine.100
  d16
  (H1_90 ph1):H
  d13
  (N15_90 ph1):N
  d13
  GRAD7:gp7			; 1.0ms, 30G/cm, z, sine.100
  TAUA7
  d16
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA7
  GRAD7:gp7			; 1.0ms, 30G/cm, z, sine.100
  d16
  (N15_90 ph0):N
  d13
  (H1_90 ph0):H
  DELTA
  (H1_180 ph0):H
  d13
  GRAD8:gp8			; 273.5u, 30G/cm, ma, sine.20
  d13
  d16 BLKGRAMP

  go=2 ph31

#ifdef ONE_D
  d11 wr #0
#else
  d11 wr #0 if #0 zd
#endif
  d13 LOCKH_OFF
#ifdef N15_EVOL
  3m igrad EA
  d14 ip14
  d14 ip14
  lo to 3 times 2
  d14 dd10
  d14 id30
  d14 ip12
  d14 ip12
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd10
  d14 rd30
#else
  d14*10
  3m
#endif
#ifdef CO_EVOL
  d14 ip11
  lo to 5 times 2
  d14 id0 
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 0 2 2
ph12=1 3
ph13=0 0 0 0 2 2 2 2
ph14=0
ph19=1			; phase y on Bruker DMX
ph21=(360) 270		; phase ph19+180
ph31=0 2 2 0