;n15hsqcse.fa
;2D 15N-HSQC-SE, with optional FLIP-BACK pulse and C13 decoupling
;Zhang et al., J. Bio. NMR, 4, 845-858 (1994)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: n15hsqcse.fa,v 1.3 2001/06/07 17:14:02 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C
;o1p: 4.7ppm
;o2p: 118ppm
;o3p: 43ppm (optional)
;
;d1: relaxation delay=d1+0.100s
;p1 90 H1 at pl1
;p2 90 N15 at pl2
;p3 90 C13 at pl3 (for optional C decoupling)
;p11 H1 2ms selective water flip-back pulse at power pl11. 
; Check for phase difference between hard H1 and soft H1 
; pulses and set phcor21 accordingly.
;
;N15 Waltz-16 (cpdprg2), using p90 (PCPD) at pl12
;N15 evolution:
;  in0, SW(N)=1/(2*in0)
;  l4 complex points. Set '1 td' to 2*l4.
;  Quadrature detection in t1 by echo-antiecho, with axial peaks
;  at edge of spectrum.
;  initial delay = in0; Phase correction: ph0=90, ph1=-180.
;
;ns=2, 4, ..., ds=2, 4, ...
;
;Recommendations for gradients, triple axis (or single axis):
;gpz1: 6%
;gpz2: 10%
;gpz3: -22%
;gpx4: 54% (0%)
;gpz4: 30% (60%)
;gpx5: 54% (0%)
;gpz5: 30% (60%)
;gpnam1: sine.100
;gpnam2: sine.50
;gpnam3: sine.100
;gpnam4: sine.100
;gpnam5: sine.20
;
;Coherence selection gradient pair (GRAD4/GRAD5) may be optimized
;by varying p19 (uncomment OPTIM_P19). Theoretical value of p19 is 131.7 us.
;
;#define ONE_D
#define C13_LABEL
#define FLIP_BACK
;#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD5)
;#define MESSERLE	; don't use Messerle pulse with flip-back option
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
;
#define H f1
#define N f2
#define C f3
;
;You shouldn't have to worry about anything beyond this point :-)
;
;
#ifdef FLIP_BACK
#undef MESSERLE
#endif

define delay TAUA
define delay TAUA2
define delay TAUB
define delay DELTA
define delay CEN_HN1
define delay CEN_HC1
define pulse H1_90
define pulse H1_180
define pulse N15_90
define pulse N15_180
define pulse C13_90
define pulse C13_180
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD4
define pulse GRAD5

"d11=100m"                      ;disk i/o
"d12=10u"                       ;power switching etc.
"d13=5u"                        ;a short delay
"d14=60u"			;ip, id etc.
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"N15_90=p2"
"N15_180=N15_90*2"
"CEN_HN1=N15_90-H1_90"

"GRAD1=1.0m"
"GRAD2=500u"
"GRAD3=1.5m"
"GRAD4=1.3m"
#ifndef OPTIM_P19
  "p19=131.7u"
#endif
"GRAD5=p19"

;"l4=td1/2"
#ifdef ONE_D
  "d0=d13"
#else
  "d0=d13+in0/2"
#endif

"TAUA=2.3m"			;1/(4Jnh)
"d6=H1_90"
"d7=N15_90"
"TAUA2=TAUA-GRAD2-d13-d16"
"DELTA=GRAD5+d16+d13*2"
#ifdef C13_LABEL
  "C13_90=p3"
  "C13_180=C13_90*2"
  "TAUB=d16+GRAD4+d13*5+C13_90*4"
  "CEN_HC1=C13_180-H1_90+d13"
#else
  "TAUB=d16+GRAD4+d13*3+H1_180"
#endif

#ifdef EXPTCORR
  "d31=6*(TAUA2+GRAD2)+GRAD1+GRAD3+GRAD4+GRAD5+TAUB+DELTA"
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d13 do:N
  d11 LOCKH_OFF
  3m
  d14
  d14
3 d14
  d14
  d14
  d14
  d14
4 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d1 pl1:H pl2:N pl3:C
  d13 LOCKH_ON
  d13 UNBLKGRAMP
; Purge N15
  (N15_90 ph0):N
  d13
  GRAD1:gp1		;1m, 4G/cm
  d16
; Start INEPT
  (H1_90 ph0):H
  d13
  GRAD2:gp2		;500u, 7G/cm
  d16
  TAUA2
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA2
  GRAD2:gp2		;500u, 7G/cm
  d16
#ifdef MESSERLE
  (H1_90*55 ph0):H
  d13
#endif
  (H1_90 ph1):H
#ifdef FLIP_BACK
  d13
  d12 pl11:H
  (p11 ph21:r):H        ;2ms 90 H1 pulse at phase -x
  d13
  d12 pl1:H
#endif
  d13
  GRAD3:gp3		;1.5m, -15G/cm
  d16 
  (N15_90 ph11):N
  d0 
#ifdef C13_LABEL
  (CEN_HC1 H1_180 ph0):H (C13_90 ph0 d13 C13_180 ph1 d13 C13_90 ph0):C
#else
  (H1_180 ph0):H
#endif
  d0 
  d13
  GRAD4:gp4*EA		;1.3m, +/-30G/cm
  d16
  (N15_180 ph0):N
  TAUB
  (N15_90 ph12):N
  d6
  (H1_90 ph0):H
  d13
  GRAD2:gp2		;500u, 7G/cm
  d16
  TAUA2
  (N15_180 ph0):N
  (H1_180 ph0):H 
  d13
  TAUA2
  GRAD2:gp2		;500u, 7G/cm
  d16
  d7
  (N15_90 ph1):N
  (H1_90 ph1):H 
  d13
  GRAD2:gp2		;500u, 7G/cm
  d16
  TAUA2
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA2
  GRAD2:gp2		;500u, 7G/cm
  d16
  (H1_90 ph0):H
  DELTA pl12:N
  (H1_180 ph0):H
  d13
  GRAD5:gp5		;130u, 30G/cm
  d13
  d16 BLKGRAMP
  go=2 ph31 cpd2:N

#ifdef ONE_D
  d11 do:N wr #0
  d13 LOCKH_OFF
#else
  d11 do:N wr #0 if #0 zd
  d13 LOCKH_OFF
  3m igrad EA
  d14 ip12
  d14 ip12
  lo to 3 times 2
  d14 id0 
  d14 ip11
  d14 ip11
  d14 ip31
  d14 ip31
  lo to 4 times l4
#endif

exit
  
ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 2
ph12=0
ph21=2
ph31=0 2