;n15t2gp.fa
;2D 15N-T2-HSQC-SE, with FLIP-BACK pulse
;Farrow et al., Biochemistry 33, 5984-6003 (1994).
;Bruker Avance/Xwin-nmr version. For XWIN-NMR 2.5+
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
; $Id: n15t2.fa,v 1.4 2000/10/29 18:24:27 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm
;
;d1: relaxation delay=d1+0.100s
;p1 90 H1 at pl1
;p2 90 N15 at pl2
;p22 90 N15 at pl22 (for CPMG sequence)
;p11
;   90 H1 2ms selective water flip-back pulse at power pl11. 
;   Check for phase difference between hard H1 and soft H1 
;   pulses and set phcor21 accordingly.
;   Use zgsel2.fa to calibrate.
;pl0 120dB
;Relaxation delay (T): l9*16*500u = l9*8ms
;Coherence selection gradient pair (GRAD5/GRAD7) may be optimized
;by varying p19 (uncomment OPTIM_P19). Theoretical value of p19 is 131.7u.
;
;N15 Waltz-16 (cpdprg2), using p90 (PCPD) at pl12
;N15 evolution:
;  in0, SW(N)=1/(2*in0)
;  l4 complex points. Set '1 td' to 2*l4.
;  Quadrature detection in t1 by echo-antiecho, with axial peaks
;  at edge of spectrum.
;
;ns=8, 16, ..., ds=8, 16, ...
;
;Recommendations for gradients:
;gpz1: 6% (6%)
;gpz2: 10% (10%)
;gpz3: -22% (-22%)
;gpx5: 54% (0%)
;gpz5: 30% (55%)
;gpz6: 15% (15%)
;gpx7: 54% (0%)
;gpz7: 30% (55%)
;gpnam1: sine.100
;gpnam2: sine.50
;gpnam3: sine.100
;gpnam5: sine.100
;gpnam6: sine.50
;gpnam7: sine.20
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
;#define OPTIM_P19	; uncomment if you want to optimize p19 (GRAD7)
#define EXPTCORR	; uncomment if you want "expt" to report
;			; the correct expt time (works with XWIN-NMR 2.x)
;
;Define channel assignments:
#define H f1
#define N f2
;
;You shouldn't have to worry about anything beyond this point :-)
;
define delay TAUA
define delay TAUB
define delay TAUB1
define delay TAUB2
define delay TAUB3
define delay TAUC
define delay DELTA
define delay DELTA1
define delay CEN_HN1
define pulse H1_90
define pulse H1_180
define pulse N15_90
define pulse N15_180
define pulse CPMG180
define pulse GRAD1
define pulse GRAD2
define pulse GRAD3
define pulse GRAD5
define pulse GRAD6
define pulse GRAD7

"d11=100m"                      ;disk i/o
"d12=10u"                       ;power switching etc.
"d13=5u"                        ;a short delay
"d14=60u"                       ;ip,id etc.
"d16=300u"                      ;gradient recovery
"d0=d13"
"d2=2.25m"			;1/(4Jnh)
"H1_90=p1"
"H1_180=H1_90*2"
"N15_90=p2"
"N15_180=N15_90*2"
"CPMG180=p22*2"
"GRAD1=1.0m"
"GRAD2=500u"
"GRAD3=1.5m"
"GRAD5=1.3m"
#ifndef OPTIM_P19
"p19=131.7u"
#endif
"GRAD7=p19"
"GRAD6=500u"
;"l4=td1/2"
"TAUA=d2-GRAD2-d13-d16"
"TAUB=2.75m"
"TAUB1=TAUB-GRAD6-d16-N15_90*0.637"
"TAUB2=TAUB-GRAD6-d16"
"TAUB3=TAUB-GRAD5-d16-N15_90*0.637-H1_180-d0*2"
"TAUC=500u"
"DELTA=500u-CPMG180/2"
"DELTA1=DELTA-H1_90"
"d6=H1_90"
"d7=N15_90"
"d25=TAUC-GRAD7-d13"
"CEN_HN1=N15_90-H1_90"

#ifdef EXPTCORR
  "d31=6*(TAUA+GRAD2)+TAUB+TAUB1+TAUB2+TAUB3+TAUC+DELTA*16*l9+GRAD3+GRAD5+GRAD7+2*GRAD6"
#endif

#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d11 do:N
  3m
  d14
  d14
3 d14
  d14
  d14
  d14
  d14
4 d14 LOCKH_OFF
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif  
  d1 pl1:H pl2:N
  d14 LOCKH_ON
  (N15_90 ph0):N
  d13
  GRAD1:gp1		;1m, 4G/cm
  d16
  (H1_90 ph0):H
  d13
  GRAD2:gp2		;500u, 7G/cm
  d16
  TAUA
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA
  GRAD2:gp2		;500u, 7G/cm
  d16
  (H1_90 ph1):H
  d13
  d12 pl11:H
  (p11 ph21:r):H        ;2ms 90 H1 pulse at phase -x
  d13
  d12 pl1:H
  d13
  GRAD3:gp3		;1.5m, -15G/cm
  d16 
  (N15_90 ph11):N
;  d14
  TAUB1
  GRAD6:gp6		;500u, 10G/cm
  d16
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d16
  GRAD6:gp6		;500u, 10G/cm
  TAUB2 pl22:N
;  d14 LOCKH_OFF
9 DELTA
  (CPMG180 ph0):N
  DELTA
  DELTA
  (CPMG180 ph0):N
  DELTA1
  (H1_180 ph0):H
  DELTA1
  (CPMG180 ph0):N
  DELTA
  DELTA
  (CPMG180 ph0):N
  DELTA
  DELTA
  (CPMG180 ph0):N
  DELTA
  DELTA
  (CPMG180 ph0):N
  DELTA1
  (H1_180 ph2):H
  DELTA1
  (CPMG180 ph0):N
  DELTA
  DELTA
  (CPMG180 ph0):N
  DELTA
  lo to 9 times l9
  TAUB pl2:N
;  d14 LOCKH_ON
  (N15_180 ph12):N
  d0
  (H1_180 ph0):H
  d0
  TAUB3
;  d14
  GRAD5:gp5*EA		;1.3m, +/-30G/cm
  d16
  (N15_90 ph13):N
  d6
  (H1_90 ph0):H
  d13
  GRAD2:gp2		;500u, 7G/cm
  d16
  TAUA
  (N15_180 ph0):N
  (H1_180 ph0):H 
  d13
  TAUA
  GRAD2:gp2		;500u, 7G/cm
  d16
  d7
  (N15_90 ph1):N
  (H1_90 ph1):H 
  d13
  GRAD2:gp2		;500u, 7G/cm
  d16
  TAUA
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA
  GRAD2:gp2		;500u, 7G/cm
  d16
  (H1_90 ph2):H
  TAUC
  (H1_180 ph0):H
  d13
  GRAD7:gp7		;130u, 30G/cm
  d25 pl12:N
  go=2 ph31 cpds2:N

#ifdef ONE_D
  d11 do:N wr #0
#else
  d11 do:N wr #0 if #0 zd
  3m igrad EA
  d14 ip13
  d14 ip13
  lo to 3 times 2
  d14 id0 
  d14 ip11
  d14 ip11
  d14 ip31
  d14 ip31
  lo to 4 times l4
#endif

  d14 LOCKH_OFF

exit
  
ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 2
ph12=0 0 1 1 2 2 3 3
ph13=0
ph21=2
ph31=0 2 2 0