;n15tochsqcse.fa
;3D TOCSY-15N-HSQC-SE, with FLIP-BACK pulse and optional C13 decoupling
;Zhang et al., J. Bio. NMR, 4, 845-858 (1994)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;Version: 01/28/1998
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C
;o1p: 4.7ppm
;o2p: 118ppm
;o3p: 43ppm (optional)
;use gradient program fatochsqcse
;
;p1 90 H1 at pl1
;p2 90 N15 at pl2
;p3 90 C13 at pl3 (for optional C decoupling)
;p31 90 H at pl10 for isotropic mixing
;p11 90 H1 weak regular pulse at power pl11, 2ms. 
; Check for phase difference between hard H1 and soft H1 
; pulses and set phcor12 accordingly.
;N15 Waltz-16 PCPD2 at pl12, cpdprg2
;H1 evolution:
;   SW(H)=1/2*in10
;   set cnst10 to 0 (preferably) or 1 to make d10 the smallest possible
;   positive delay: d10=((cnst10*2+1)*in10-(p1*1.273+p2*2))/2
;   l6 complex points
;N15 evolution:
;   SW(N)=1/2*in0
;   l4 complex points
;ns=4, 8, ..., ds=2*ns*m, m=1, 2, ...

;
;Recommendations for gradients:
;p15=500u
;p16=1.5m
;p18=1.25m
;p19=125u
;p17=1m
;cnst23=4G/cm
;cnst24=7G/cm
;cnst25=30G/cm
;cnst26=-15G/cm
;cnst27/28=-/+30G/cm
;cnst30=1.800 (adjust) for magic angle gradient (Gx/Gz) or 0 for Gz only.

;#define ONE_D		; uncomment for 1D experiment
#define H1_EVOL 	; comment out for 2D w/o H1 evolution
#define N15_EVOL	; comment out for 2D w/o N15 evolution
#define C13_LABEL	; uncomment for C13 decoupling
;Select an isotropic mixing scheme
;#define DIPSI2		; taum = 115.112*p31*l9
#define DIPSI2RC	; taum = 172.668*p31*l9
;#define DIPSI3		; taum = 217.336*p31*l9
#define EXPTCORR	; uncomment if you want "expt" to report
			; the correct exp. time (works with XWIN-NMR 2.x)
#define FLIP_BACK	; uncomment for optional Flip-Back pulse for min. water saturation
;#define MESSERLE	; don't use Messerle pulse with flip-back option
;
;You shouldn't have to worry about anything beyond this point :-)
#ifdef ONE_D
#undef H1_EVOL
#undef N15_EVOL
#endif
;
#define H f1
#define N f2
#define C f3
#ifdef FLIP_BACK
#undef MESSERLE
#endif
define delay TAUA
define delay TAUB
define delay TAUC
define delay RCDELAY
define pulse H1_90
define pulse H1_180
define pulse N15_90
define pulse N15_180
define pulse C13_90
define pulse C13_180
"d11=100m"                      ;disk i/o
"d12=10u"                       ;power switching etc.
"d13=5u"                        ;a short delay
"d14=40u"			;ip, id etc.
"d16=300u"			;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"N15_90=p2"
"N15_180=N15_90*2"
"d0=d13"
#ifdef H1_EVOL
  "d10=((cnst10*2+1)*in10-(H1_90*1.273+N15_180))/2"
#endif
"d6=H1_90"
"d7=N15_90"
"d5=500u"
"TAUA=2.25m-p15-d13-d16"
"TAUB=1.5m"
"TAUC=500u"
"d25=d5-p19-d13"
"d29=N15_90-H1_90"
#ifdef C13_LABEL
  "C13_90=p3"
  "C13_180=p3*2"
  "d24=TAUB-p18-d13+d0*2+C13_90*4+d13*2"
  "d28=C13_180-H1_90+d13"
#else
  "d24=TAUB-p18-d13+d0*2+H1_180"
#endif
#ifdef DIPSI2RC
  "RCDELAY=p31*1.599"
#endif
#ifdef EXPTCORR
  "d31=6*TAUA+TAUB+TAUC"
#endif

#include <Avance.incl>
#include <Gradfa.incl>

1 ze
2 d11 do:N
  d14
  d14
3 d14
  d14
  d14
  d14
  d14
4 d14
  d14
  d14
5 d14
  d14
  d14
6 d14 LOCKH_OFF
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d1 pl1:H pl2:N pl3:C
  d14 LOCKH_ON
  (N15_90 ph0):N
  d13
  GRADIENT17(cnst23)   ;1m, 4G/cm
  d16
  (H1_90 ph11):H
#ifdef H1_EVOL
  d10
#ifdef C13_LABEL
  (N15_180 ph0):N (C13_90 ph0 d13 C13_180 ph1 d13 C13_90 ph0):C
#else
  (N15_180 ph0):N
#endif
  d10
#else
  d13
#endif
  (H1_90 ph1):H
  d13
  d12 pl10:H
9 d13
#ifdef DIPSI2
#include <dipsi2f1.incl>
#endif
#ifdef DIPSI2RC
#include <dipsi2rcf1.incl>
#endif
#ifdef DIPSI3
#include <dipsi3f1.incl>
#endif
  lo to 9 times l9
  d13
  d12 pl1:H
  (H1_90 ph0):H
  d13
  GRADIENT15(cnst24)   ;500u, 7G/cm
  d16
  TAUA
  (d29 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA
  GRADIENT15(cnst24)   ;500u, 7G/cm
  d16
#ifdef MESSERLE
  (H1_90*55 ph0):H
  d13
#endif
  (H1_90 ph1):H
#ifdef FLIP_BACK
  d13
  d12 pl11:H
  (p11 ph12:r):H        ;2ms 90 H1 pulse at phase x,-x
  d13
  d12 pl1:H
#endif
  d13
  GRADIENT16(cnst26)   ;1.5m, -15G/cm
  d16 
  (N15_90 ph13):N
  d0 
#ifdef C13_LABEL
  (d28 H1_180 ph0):H (C13_90 ph0 d13 C13_180 ph1 d13 C13_90 ph0):C
#else
  (H1_180 ph0):H
#endif
  d0 
  TAUB
  (N15_180 ph0):N
  d13
  GRADIENT18(cnst25)   ;1.25m, 30G/cm
  d24
  (N15_90 ph14):N
  d6
  (p1 ph0):H
  d13
  GRADIENT15(cnst24)   ;500u, 7G/cm
  d16
  TAUA
  (N15_180 ph0):N
  (H1_180 ph0):H 
  d13
  TAUA
  GRADIENT15(cnst24)   ;500u, 7G/cm
  d16
  d7
  (N15_90 ph1):N
  (H1_90 ph1):H 
  d13
  GRADIENT15(cnst24)   ;500u, 7G/cm
  d16
  TAUA
  (d29 H1_180 ph0):H (N15_180 ph0):N
  d13
  TAUA
  GRADIENT15(cnst24)   ;500u, 7G/cm
  d16
  (H1_90 ph0):H
  TAUC
  (H1_180 ph0):H
  d13
  GRADIENT19(cnst27)   ;125u, -/+30G/cm
  d25 pl12:N
  go=2 ph31 cpd2:N

#ifdef ONE_D
  d11 do:N wr #0
#else
  d11 do:N wr #0 if #0 zd
#endif
#ifdef N15_EVOL
  d14 ip14
  d14 ip14
  lo to 3 times 2
  d14 id0 
  d14 ip13
  d14 ip13
  d14 ip31
  d14 ip31
  lo to 4 times l4
  d14 rd0
#endif
#ifdef H1_EVOL
  d14 ip11
  d14 dp12
  lo to 5 times 2
  d14 id10
  d14 ip31
  d14 ip31
  lo to 6 times l6
#endif

 d14 LOCKH_OFF

exit
  
ph0=0
ph1=1
ph2=2
ph3=3
ph11=1 3
ph12=0 2
ph13=0 0 2 2
ph14=0
ph31=0 2 2 0