;noesy3919.fa
;2D Homonuclear NOESY, with Watergate (3-9-19), TPPI in F1
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: noesy3919.fa,v 1.3 2001/06/21 20:47:01 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H
;o1p: 4.7ppm
;
;d1 relaxation delay=d1+0.1s
;p1 90 H1 at pl1 (high power)
;d8 mixing time
;d21: 1/(2*dNu), dNu=Nu(NH)-Nu(H2O)
;H1 evolution:
;   SW(H)=1/(2*in0)
;   l4 real points (TPPI), "1 td" = l4
;   in0 is adjusted to give sine-modulated data in t1 - use "shr 1"
;      in this dimension during processing (Felix).
;ns=16, 32, ..., ds=16, 32, ...
;
;Recommendations for gradients:
;gpz2:  30%
;gpx3:  54%,adjust for ma (0%)
;gpz3:  30% (55%)
;gpnam2: sine.100
;gpnam3: sine.100
;
;Define one or more of the following options to tailor this pulse program
; to your specific needs.
;
;#define ONE_D		; uncomment for 1D experiment
#define EXPTCORR	; uncomment if you want "expt" to report
			; the correct exp. time (works with XWIN-NMR 2.x)
;
;You shouldn't have to worry about anything beyond this point :-)
;
define delay TAUM
define delay TAUW
define pulse H1_90
define pulse H1_180
define pulse GRAD2
define pulse GRAD3
"d11=100m"                      ;disk i/o
"d13=5u"                        ;a short delay
"d14=40u"                       ;ip,id etc.
"d16=300u"                      ;gradient recovery
"H1_90=p1"
"H1_180=H1_90*2"
"d6=H1_90"
;
"GRAD2=1.0m"
"GRAD3=700u"
"TAUW=d21"
"TAUM=d8-GRAD2-d16"

#ifndef ONE_D
  "d0=in0-1.2732*H1_90"
#else
  "d0=d13"
#endif

#ifdef EXPTCORR
  "d31=5*TAUW+TAUM+GRAD2+2*GRAD3"
#endif
;
#include <Avance.incl>
#include <Grad.incl>
;
1 ze
2 d11 LOCKH_OFF
  d14
  d14
4 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d1 pl1:f1
  d13
  d13 UNBLKGRAMP
  (H1_90 ph5):f1
  d0
  (H1_90 ph6):f1
  TAUM LOCKH_ON
  GRAD2:gp2		;1.0ms, 20G/cm
  d16
  (H1_90 ph7):f1
  d13
  GRAD3:gp3		;700u, 40G/cm
  d16
  (H1_90*0.231 ph20):f1
  TAUW
  (H1_90*0.692 ph20):f1
  TAUW
  (H1_90*1.462 ph20):f1
  TAUW
  (H1_90*1.462 ph22):f1
  TAUW
  (H1_90*0.692 ph22):f1
  TAUW
  (H1_90*0.231 ph22):f1
  d13
  GRAD3:gp3		;700u, 40G/cm
  d16
  d6 BLKGRAMP
  go=2 ph31
#ifdef ONE_D
  d11 wr #0
  d13 LOCKH_OFF
#else
  d11 wr #0 if #0 zd
  d13 LOCKH_OFF
  d14 id0
  d14 ip5
  lo to 4 times l4
#endif

exit

ph0=0
ph1=1
ph2=2
ph3=3
ph5=0 2 0 2 1 3 1 3
ph6=0 0 2 2 1 1 3 3
ph7=0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3
ph20=0 0 0 0 1 1 1 1
ph22=2 2 2 2 3 3 3 3
ph31=0 2 2 0 1 3 3 1 2 0 0 2 3 1 1 3