;roesy3919.fa
;2D Homonuclear ROESY, with Watergate (3-9-19), TPPI in F1
;Griesinger and Ernst, J Magn Reson 75, 261-271 (1987)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: roesy3919.fa,v 1.2 1998/04/24 03:52:41 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H
;Gradient program: faroesy3919
;o1p: 4.7ppm
;
;d1 relaxation delay=d1+0.1s
;p1 90 H1 at pl1 (high power)
;p9 ROESY mixing time at spin lock power pl9 (~5kHz at 500MHz)
;  adjust phcor9 to compensate for any phase difference between pl1 and pl9
;d21: 1/(2*dNu), dNu=Nu(NH)-Nu(H2O)
;H1 evolution:
;   SW(H)=1/(2*in0)
;   l4 real points (TPPI), "1 td" = l4
;   in0 is adjusted to give sine-modulated data in t1 - use "shr 1"
;      in this dimension during processing (Felix).
;ns=8, 16, ..., ds=8, 16, ...
;
;Recommendations for gradients:
;p17=700u
;cnst23=20% (40G/cm combined x,z)
;cnst30=1.800 (adjust for magic angle) or set to 0 for Gz only
;

;#define ONE_D		;uncomment for 1D version
;
;You shouldn't have to worry about anything beyond this point :-)
;
"d11=100m"
"d13=5u"
"d14=40u"
"d16=300u"
;
#ifndef ONE_D
"d0=in0-1.2732*p1"
#else
"d0=3u"
#endif
;
#include <Avance.incl>
#include <Gradfa.incl>
;
1 ze
2 d11
  d14
  d14
4 d13
  d14 LOCKH_OFF
  d1 pl1:f1
  d14 LOCKH_ON
  (p1 ph5):f1
  d0 
  (p1 ph6):f1
  d13
  d12 pl9:f1
  (p9 ph9:r):f1
  d13
  d12 pl1:f1
  (p1 ph6):f1
  d13
  GRADIENT17(CNST23)
  d16
  (p1*0.231 ph20):f1
  d21
  (p1*0.692 ph20):f1
  d21
  (p1*1.462 ph20):f1
  d21
  (p1*1.462 ph22):f1
  d21
  (p1*0.692 ph22):f1
  d21
  (p1*0.231 ph22):f1
  d13
  GRADIENT17(CNST23)
  d16
  go=2 ph31
#ifdef ONE_D
   d11 wr #0
#else
  d11 wr #0 if #0 zd
  d14 id0
  d14 ip5
  lo to 4 times l4
#endif
  d14 LOCKH_OFF
exit


ph5=0 2 2 0 1 3 3 1
ph6=0 0 2 2 1 1 3 3
ph9=0 0 2 2 1 1 3 3
ph20=0 0 2 2 1 1 3 3
ph22=2 2 0 0 3 3 1 1
ph31=0 2 2 0 1 3 3 1