;trosy.fa
;2D 15N-1H-TROSY with 3-9-19 watergate
;Pervushin et al., Proc. Natl. Acad. Sci. USA 94, 12366-12371 (1997)
;Bruker Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: trosy.fa,v 1.1 1999/07/26 03:13:31 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N  (channel assignments may be changed below)
;Gradient program: fatrosy
;o1p: 4.7ppm
;o2p: 118ppm
;
;p1 90 H1 at pl1
;p2 90 N15 at pl2
;d21: 1/(2*dNu), dNu=Nu(NH)-Nu(H2O), 300us at 500MHz, 200us at 750MHz
;N15 evolution:
;   SW(N)=1/(2*in0)
;   l4 complex points. Set '1 td' to 2*l4.
;   Process as States. Initial delay in t1 is DW(N)/2
;   ((90,-180) phase distortion in F1).
;ns=8,16,... ,ds=8,16,... 
;
;Recommendations for gradients:
;p15=500u
;p16=500u
;p17=700u
;p18=1m
;cnst21=6% (4G/cm)
;cnst22=8% (6G/cm)
;cnst23=20% (30-40G/cm combined x,z)
;cnst24=-40% (-50G/cm)
;cnst30=1.800 (adjust) for magic angle gradient (Gx/Gz) or 0 for Gz only.


#define ONE_D
#define EXPTCORR

;
;You shouldn't have to worry about anything beyond this point :-)
;
;Define channel assignments:
#define H f1
#define N f2
;
define delay TAUA
define delay TAUB
define delay TAUC
define delay TAUW
define pulse H1_90
define pulse H1_180
define pulse N15_90
define pulse N15_180
"d11=100m"			;disk i/o
;"d12=10u"			;power switching etc.
"d13=5u"			;a short delay
"d14=40u"			;ip,id etc.
"d16=300u"			;gradient recovery delay
"H1_90=p1"
"H1_180=p1*2"
"N15_90=p2"
"N15_180=p2*2"
"d6=H1_90"
"TAUA=2.7m-p15-d16-d13"
"TAUB=2.7m-p16-d16-d13"
"TAUW=d21"
"TAUC=2.7m-TAUW*2.5-p1*2.385-p17-d16-d13"
"d22=(TAUW/2)-N15_90"
"d29=N15_90-H1_90"


#ifdef ONE_D
  "d0=d13"
#else
  "d0=in0/2"
#endif

#ifdef EXPTCORR
  "d31=2*TAUA+2*TAUB+2*TAUC+4*4*TAUW"
#endif


#include <Avance.incl>
#include <Gradfa.incl>

1 ze
2 d11
  d14
3 d14
  d14
  d14
4 d14 LOCKH_OFF
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d1 pl1:H pl2:N
  d14 LOCKH_ON
  (H1_90 ph0):H
  d13
  GRADIENT15(cnst21)   ;500us, 4G/cm
  d16
  TAUA
  (d29 H1_180 ph3):H (N15_180 ph0):N
  TAUA
  d13
  GRADIENT15(cnst21)   ;500u, 4G/cm
  d16
  (H1_90 ph3):H
  d13
  GRADIENT18(cnst24)	;1m, -50G/cm
  d16
  (N15_90 ph11):N
  d0
  d0
  (H1_90 ph12):H
  d13
  GRADIENT16(cnst22)	;500u, 6G/cm
  d16
  TAUB
  (d29 H1_180 ph0):H (N15_180 ph0):N
  TAUB
  GRADIENT16(cnst22)	;500u, 6G/cm
  d16
#ifdef ONE_D
  d13*2
#endif
  (H1_90 ph0):H
  d13
  (N15_90 ph1):N
  d13
  GRADIENT17(cnst23)	;700u, 40G/cm
  d16
  TAUC
  (H1_90*0.231 ph0):H
  TAUW
  (H1_90*0.692 ph0):H
  TAUW
  (H1_90*1.462 ph0):H
  d22
  (N15_180 ph0):N
  d22
  (H1_90*1.462 ph2):H
  TAUW
  (H1_90*0.692 ph2):H
  TAUW
  (H1_90*0.231 ph2):H
  d13
  TAUC
  d13
  GRADIENT17(cnst23)	;700u, 40G/cm
  d16
  (N15_90 ph13):N
  d6
  go=2 ph31

#ifdef ONE_D
  d11 wr #0
#else
  d11 wr #0 if #0 zd
  d14 ip11
  lo to 3 times 2
  d14 id0
  d14 ip31
  d14 ip31
  lo to 4 times l4
#endif

d14 LOCKH_OFF

exit
  
ph0=0
ph1=1
ph2=2
ph3=3
ph11=3 1 0 2
ph12=1 1 1 1 3 3 3 3
ph13=0 0 0 0 2 2 2 2
ph31=0 2 3 1 2 0 3 1