;trosysefb.fa
;2D 15N-1H-TROSY-SE-FB with 3-9-19 watergate and optional C13 decoupling
;Rance et al., J. Magn. Reson. 136, 92-101 (1999)
;Pervushin et al., Proc. Natl. Acad. Sci. USA 94, 12366-12371 (1997)
;Bruker Avance/Xwin-nmr version. This program requires XWIN-NMR 2.x
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu)
;
;  $Id: trosysefb.fa,v 1.7 2000/06/16 17:05:42 abild Exp abild $
;
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM nor University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C  (channel assignments may be changed below)
;o1p: 4.7ppm
;o2p: 118ppm
;o3p: 120ppm
;
;p1 90 H1 at pl1
;p2 90 N15 at pl2
;p3 90 C13 at pl3 (for optional C13 decoupling)
;d1: relaxation delay
;d21: 1/(2*dNu), dNu=Nu(NH)-Nu(H2O), 300us at 500MHz, 200us at 750MHz
;N15 evolution:
;   SW(N)=1/(2*in0)
;   l4 complex points. Set '1 td' to 2*l4.
;   Process as echo-antiecho
;   set cnst0 to 0 (preferably) or 1 to adjust the initial delay in t1.
;   cnst0=0 gives DW(N)/2 initial delay ((90,-180) phase distortion in F1).
;   cnst0=1 gives 1.5*DW(N) initial delay ((270,-540) phase distortion in F1
;   (use LP to correct).
;ns=4,8,... ,ds=4,8,... 
;
;Recommendations for gradients:
;gpz1:  44%
;gpz2: 0.8%
;gpy3:  50%
;gpx4:  54% (adjust for magic-angle)
;gpz4:  30%
;gpnam1: sine.50
;gpnam3: sine.50
;gpnam4: sine.100


;#define ONE_D		; uncomment for 1D experiment
#define C13_LABEL	; uncomment for C13 decoupling
#define EXPTCORR	; uncomment to have "expt" report the correct exp. time
#define XWIN2.6		; uncomment if running XWIN-NMR 2.6 or higher -
			; if XWIN2.6 is undefined, check the value of the
			; delay PRESCD below. It should be equal to the prescan
			; delay "DE" (e.g. 6.0 us on DMX hardware)
;
;Define channel assignments:
#define H f1
#define N f2
#define C f3
;
;
;You shouldn't have to worry about anything beyond this point :-)
;

define delay TAU1
define delay TAU3
define delay TAU4
define delay TAUW
define delay TAUW1
define delay CEN_HN1
define pulse H1_90
define pulse H1_180
define pulse N15_90
define pulse N15_180
define pulse C13_90
define pulse C13_180
define pulse GRAD1
define pulse GRAD3
define pulse GRAD4
define delay DE2DE1
define delay DEDE2
define delay PRESCD

#ifdef XWIN2.6
  "PRESCD=de"
#else
  "PRESCD=6.0u"
#endif

"DE2DE1=de2-de1"
"DEDE2=PRESCD-de2"
"d11=100m"			;disk i/o
"d12=10u"			;power switching etc.
"d13=5u"			;a short delay
"d14=60u"			;ip,id etc.
"d16=300u"			;gradient recovery delay
"H1_90=p1"
"H1_180=H1_90*2"
"N15_90=p2"
"N15_180=N15_90*2"
"d6=H1_90"
"d7=N15_90"
;
"GRAD1=500u"
"GRAD3=500u"
"GRAD4=700u"
;
"TAU1=2.7m-GRAD1-d16-d13"
"TAU3=2.7m-GRAD3-d16-d13"
"TAUW=d21"
"TAUW1=(TAUW/2)-N15_90"
"TAU4=2.7m-TAUW*2.5-H1_90*2.385-GRAD4-d16-d13"
"CEN_HN1=N15_90-H1_90"
#ifdef C13_LABEL
"C13_90=p3"
"C13_180=C13_90*2"
#endif

#ifndef ONE_D
  "d17=50u"			;short gradient recovery delay
#ifdef C13_LABEL
  "d0=((cnst0*2+1)*in0-C13_90*4-d13*4-d17*2)/2"
#else
  "d0=((cnst0*2+1)*in0-d13-d17)/2"
#endif
#endif

#ifdef EXPTCORR
  "d31=2*(TAU1+TAU3+TAU4+2*TAUW+TAUW1+GRAD1+GRAD3+GRAD4)"
#endif
"l0=0"

#include <Avance.incl>
#include <Grad.incl>

1 ze
2 d13
  d11 LOCKH_OFF
  d14
  d14
  d14
  d14
  d14
3 d14
  d14
  d14
  d14
  d14
4 d13
#ifdef EXPTCORR
#include <faexptcorr.incl>
#endif
  d1 pl1:H pl2:N
#ifdef C13_LABEL
  d12 pl3:C
#endif
  d12 LOCKH_ON
  d13 UNBLKGRAMP
  (H1_90 ph0):H
  d13
  GRAD1:gp1			;500us, 4G/cm
  d16
  TAU1
  (CEN_HN1 H1_180 ph3):H (N15_180 ph0):N
  TAU1
  d13
  GRAD1:gp1			;500u, 4G/cm
  d16
  (H1_90 ph3):H
  d13
  (N15_90 ph11):N
#ifndef ONE_D
  d13
  d0 gron2			;bipolar gradient, 0.5G/cm
#ifdef C13_LABEL
  d17 groff
  (C13_90 ph0 d13 C13_180 ph1 d13 C13_90 ph0):C
  d13
#endif
  d0 gron2*-1			;bipolar gradient, -0.5G/cm
  d17 groff
#endif
  d7
  (H1_90 ph12):H
  d13
  GRAD3:gp3			;500u, 6G/cm
  d16
  TAU3
  (CEN_HN1 H1_180 ph0):H (N15_180 ph0):N
  TAU3
  GRAD3:gp3			;500u, 6G/cm
  d16
  d13
  d6
  (d7) (H1_90 ph0):H
  (N15_90 ph1):N
  d13
  GRAD4:gp4			;700u, 40G/cm
  d16
  TAU4
  (H1_90*0.231 ph20):H
  TAUW
  (H1_90*0.692 ph20):H
  TAUW
  (H1_90*1.462 ph20):H
  TAUW1
  (N15_180 ph0):N
  TAUW1
  (H1_90*1.462 ph19):H
  TAUW
  (H1_90*0.692 ph19):H
  TAUW
  (H1_90*0.231 ph19):H
  TAU4
  GRAD4:gp4			;700u, 40G/cm
  d16
  d13 BLKGRAMP
  d7
  (N15_90 ph13):N
;  start acquisition
   de1
   DE2DE1 adc ph31 syrec
   if "l0 %2 == 0" goto 30
29 (DEDE2 ph29):f1
   goto 31
30 (DEDE2 ph30):f1
31 aq
   rcyc=2

#ifdef ONE_D
  d11 wr #0
  d13 LOCKH_OFF
#else
  d11 wr #0 if #0 zd
  d13 LOCKH_OFF
  d14 iu0
  d14 ip12
  d14 ip12
  d14 ip13
  d14 ip13
  lo to 3 times 2
  d14 id0
  d14 ip11
  d14 ip11
  d14 ip31
  d14 ip31 
  lo to 4 times l4
#endif


exit
  
ph0=0
ph1=1
ph2=2
ph3=3
ph11=3 1 0 2
ph12=1
ph13=0
ph20=1
ph19=3
ph29=2 2 0 0
ph30=0 0 0 0
ph31=0 2 3 1