;hbhaconhse.bv
;3D HBHA(CO)NH - Gradient enhanced.
;Grzesiek and Bax, JBNMR (3) 185-204 (1993)
;Muhandiran and Kay, J. Magn. Reson. B 103, 203-216 (1994)
;Bruker Avance/Xwin-nmr version
;based on CBCA(CO)NH written up by F. Abildgaard,
;implemented by B. Volkman (volkman@nmrfam.wisc.edu)
;Version: 41196
;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM or University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;
;f1: 1H, f2: 15N, f3: 13C
;use gradient program bvhbhaconh(m) (m if magic angle grads used)
;
;Suitable grdprog and *.incl files are appended to
;the end of this pulse program, and should be removed and
;placed in appropriate /pp or /gp directory prior to execution
;of this pulse program.
;
;p3 90 Cab at pl3 (for 90 Cab)
;p4 90 Ca at pl4
;p5 180 CO SEDUCE1 shape at power sp5, offset CO-Cab
;p6 90 Cab at pl6 (for 180 Cab)
;p7 90 CO at power sp7 offset CO-Ca
;p8 180 CO at power sp8 offset CO-Ca
;p9 90 1H flip-back at pl9 ~1.5-2.0m
;
;H1 WALTZ16 PCPD1 at pl11
;N15 Waltz-16 PCPD2 at pl12
;Ca SEDUCE1 pcpd3 at sp4, shape seduce1, offset 0
;ds=2m*ns, m=1, 2, ..., ns=8, 16, ...
;
;SEMI-CONSTANT-TIME 1H EVOLUTION
;these values were used on DMX500-BV
;to give a 5405.4 Hz 1H spectral width
;(calculated as in 1st reference above)
;SW(1H)=1/(in25+in26-in27)
;in25=125u
;in26=88u
;in27=28u
;
;Recommendations for gradients:
;p15=500u
;p16=1m
;p17=250u
;p18=2.5m
;p19=250u
;p20=1.5m
;cnst21=8G/cm
;cnst22=20G/cm
;cnst23=15G/cm
;cnst24=20G/cm
;cnst25=30G/cm
;cnst26=20G/cm
;
;#define ONE_D
#define N15_EVOL
#define HAB_EVOL
;
aqseq 321
;
define delay TAUA
define delay TAUB
define delay TAUC
define delay TAUD
define delay TAUE
define delay TAUF
define delay TAUG
define delay TAUH
define delay T
define delay C_H_N
define delay C_H_CAB
define delay C_N_CO
define pulse H1_180
define pulse CAB_180
define pulse CA_180
define pulse CO_180
define pulse N15_180
"d0=3u"
"d20=3.6m-p17-d16"
"d10=12.4m"
"d30=12.4m-5.5m-d13*2"
"d6=p1"
"d7=p2"
"d11=100m"
"d12=10u"
"d13=5u"
"d16=200u"
"d17=50u"
"d23=d13*2+d12+p29"
"d24=p4*2"
"d25=1.5m-p6*2"
"d26=3u"
"d27=1.5m"
"TAUA=1.8m-p15-d13"
"TAUB=1.1m-p17-d16"
"TAUC=3.6m-p5-d13*3-d12*2"
"TAUD=4.4m"
"TAUE=12.4m"
"TAUF=5.5m-p18-d12-d13*2-d16-p29"
"TAUG=2.3m-p15"
"TAUH=500u"
"d18=TAUH-p19-d13"
"T=d20"
"H1_180=p1*2"
"CAB_180=p6*2"
"CA_180=p4*2"
"CO_180=p8"
"N15_180=p2*2"
"C_H_CAB=p6-p1"
"C_H_N=p2-p1"
;Use one of the following:
;if p8/2<p2:
"C_N_CO=p2-p8*0.5"
;if p8/2>p2:
;"C_N_CO=p8*0.5-p2"

#define SED_ON d13 \n d12 pl0:f3 \n d13 cpds3:f3

#define SED_OFF d13 do:f3

#define H1_DEC_ON d13 \n d12 pl11:f1 \n p29:f1 ph1 \n d13 cpds1:f1

#define H1_DEC_OFF d13 do:f1 \n p29:f1 ph3 \n d12 pl1:f1

#include <Avance.incl>
#include <Gradfa.incl>

1 ze
2 d11 do:f2
  d13*2
3 d13
  d13*5
4 d13
  d13*2
5 d13
  d13*4
6 20u LOCKH_OFF
  d1 pl1:f1 pl2:f2 pl3:f3
;  p13:c13              ;trigger pulse
;--------------------- carbon freq. on Cab ---------------
  50u fq3:f3
  (p3 ph0):f3
  20u LOCKH_ON
  d13
  GRADIENT15(cnst21)   ;500u, 8G/cm
  d16 pl6:f3
;------------- Semi-constant time 1H/Inept to Ca/b --------
  (p1 ph11):f1
  d25
  (CAB_180 ph0):f3
  d26
  (H1_180 ph0):f1
  3u
  d27
  (p1 ph1):f1
  d13
  GRADIENT16(cnst22)   ;1m, 20G/cm
  d16 pl3:f3
  (p3 ph0):f3
;--------------------- INEPT Ca/b to Ca ------------------
  GRADIENT17(cnst24)   ;250u, 20G/cm
  d16
  (T) (TAUB H1_180 ph0):f1
  d12 pl6:f3
  (CAB_180 ph0):f3
  d20
  GRADIENT17(cnst24)   ;250u, 20G/cm
  d16
  d12 pl3:f3
;----------------------- INEPT to C' ---------------------
  (p3 ph0):f3
  H1_DEC_ON
  d12 pl0:f3
  (p5:sp5 ph0):f3
  d13
  TAUC pl6:f3
  (CAB_180 ph12):f3
  d12 pl0:f3
  (p5:sp5 ph0):f3
  d13
  TAUC pl3:f3
  d23
  (p3 ph0):f3
  H1_DEC_OFF
  GRADIENT16(cnst23)   ;1m, 15G/cm
;----------------------- Switch frequency to Ca --------------
  d16 fq3:f3
  H1_DEC_ON
;----------------------- INEPT to N --------------------------
  d12 pl0:f3
  (p7:sp7 ph13):f3
  d13
  d12 pl4:f3
  (TAUE) (TAUD CA_180 ph0):f3
  d12 pl0:f3
  d24
  (CO_180:sp8 ph0):f3
  (TAUE) (N15_180 ph0):f2
  d12 pl4:f3
  (CA_180 ph0):f3
  d13
  d12 pl0:f3
  (p7:sp7 ph0):f3
  H1_DEC_OFF
  GRADIENT20(cnst26)     ;1.5m, 20G/cm
  d16 pl0:f3
  SED_ON
  H1_DEC_ON
  (p2 ph14):f2
  d10
  SED_OFF
  d12 pl0:f3
  (C_N_CO CO_180:sp8 ph0):f3 (N15_180 ph15):f2
  SED_ON
  d30
  H1_DEC_OFF
  TAUF
  SED_OFF
  d13
  GRADIENT18(cnst25)     ;2.5m, 30G/cm
  d16
  (p2 ph16):f2
  d6
  (p1 ph0):f1
  d13
  GRADIENT15(cnst21)     ;500u, 8G/cm
  TAUG
  (N15_180 ph0):f2
  (H1_180 ph0):f1
  d13
  GRADIENT15(cnst21)     ;500u, 8G/cm
  TAUG
  d7
  (p2 ph1):f2
  (p1 ph1):f1
  d13
  GRADIENT15(cnst21)     ;500u, 8G/cm
  TAUG
  (C_H_N H1_180 ph0):f1 (N15_180 ph0):f2
  d13
  GRADIENT15(cnst21)     ;500u, 8G/cm
  TAUG
  (p1 ph0):f1
  TAUH
  (H1_180 ph0):f1
  d13
  GRADIENT19(cnst27)     ;250u, -+30G/cm
  d18 pl12:f2
  go=2 ph31 cpd2:f2
#ifdef ONE_D
  d11 do:f2 wr #0
#else
  d11 do:f2 wr #0 if #0 zd
#endif
#ifdef N15_EVOL
  d13 ip16
  d13 ip16
  lo to 3 times 2
  d13 dd10
  d13 id30
  d13 ip14
  d13 ip14
  d13 ip31
  d13 ip31
  lo to 4 times l4
  d13 rd10
  d13 rd30
#endif
#ifdef HAB_EVOL
  d13 ip11
  lo to 5 times 2
  d13 id25
  d13 id26
  d13 dd27
  d13 ip31
  d13 ip31
  lo to 6 times l6
#endif
  20u LOCKH_OFF
exit

ph0=0
ph1=1
ph2=2
ph3=3
ph11=0
ph12=0 2
ph13=0 2
ph14=0
ph15=0 0 2 2
ph16=0
ph31=0 2

***** Gradient Program - remove this and following
**** lines before executing pulse program
** bvhbhaconhm.r ****

loop ns
{
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p16 { (0) | (0) | (0)+(cnst22) }
    { (0) | (0) | (0)          }
p17 { (0) | (0) | (0)+(cnst24) }
    { (0) | (0) | (0)          }
p17 { (0) | (0) | (0)+(cnst24) }
    { (0) | (0) | (0)          }
p16 { (0) | (0) | (0)+(cnst23) }
    { (0) | (0) | (0)          }
p20 { (0) | (0) | (0)+(cnst26) }
    { (0) | (0) | (0)          }
p18 { (0)+(cnst25*1.800) | (0) | (0)+(cnst25) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p19 { (0)+(cnst27*1.800) | (0) | (0)+(cnst27) }
    { (0) | (0) | (0)          }
}
loop ns
{
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p16 { (0) | (0) | (0)+(cnst22) }
    { (0) | (0) | (0)          }
p17 { (0) | (0) | (0)+(cnst24) }
    { (0) | (0) | (0)          }
p17 { (0) | (0) | (0)+(cnst24) }
    { (0) | (0) | (0)          }
p16 { (0) | (0) | (0)+(cnst23) }
    { (0) | (0) | (0)          }
p20 { (0) | (0) | (0)+(cnst26) }
    { (0) | (0) | (0)          }
p18 { (0)+(cnst25*1.800) | (0) | (0)+(cnst25) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p19 { (0)+(cnst28*1.800) | (0) | (0)+(cnst28) }
    { (0) | (0) | (0)          }
}


;Gradfa.incl  -  include file for Gradient Spectroscopy
;avance-version
;version 94/06/27

;
;#define GRADIENT15(ampl) p15:ngrad:c34
;#define GRADIENT16(ampl) p16:ngrad:c34
;#define GRADIENT17(ampl) p17:ngrad:c34
;#define GRADIENT18(ampl) p18:ngrad:c34
;#define GRADIENT19(ampl) p19:ngrad:c34
;#define GRADIENT20(ampl) p20:ngrad:c34


;#define BLKGRAD  setnmr2^0 setnmr0^34

;#define UNBLKGRAD setnmr2|0 setnmr0|34

;#define BLKGRAMP setnmr0^34

;#define UNBLKGRAMP setnmr0|34