;hnha.bv
;3D HNHA for determination of J3aN
;Kuboniwa, Grzesiek, Delaglio and Bax, JBNMR 4, (1994) 871-878.
;Vuister and Bax, JACS 1993, 115, 7772-7777.
;Bruker Avance/Xwin-nmr version

;Implemented and tested on DMX-600 and by B. Volkman, 
;volkman@nmrfam.wisc.edu.  6/15/96

;Suitable grdprog and *.incl files are included in this archive
;should be placed in appropriate /pp or /gp directory prior to execution
;of this pulse program.

;  Disclaimer: This pulse program is provided "as is" for your
;  information. Support for the use of this pulse program is only
;  provided to users of the National Magnetic Resonance Facility
;  at Madison (NMRFAM). Users of this pulse program employ it at
;  their own risk. Neither NMRFAM or University of Wisconsin-Madison
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.


;f1: 1H, f2: 15N
;use gradient program bvhnha
;***** RF pulses *****
;p0 90 1H at pl1 **adjust for water suppression**
;	usually ~0.1 us less than p1
;p1 90 1H at pl1 (for 90 Cab)
;p2 90 15N at pl2
;pcpd2 90 15N at pl12 (Waltz-16 dec)

;**** incremented delays ****
;in0 = 1/[2*sw(1H)]
;in10= 1/[2*sw(15N)]

;*****delays  *****
;set sampling delay for 1Ha dimension with cnst0:
"d0=((cnst0*2+1)*in0-p1*1.273-p2*2)/2"
;   set cnst0 to 1,2,3... for sampling delay of
;   1/2dw, 3/2dw, ... to give phasing of 1Ha dim. of 
;   (90, -180,no lpf), (90, -180,lpf 1st pnt)...
;d1 - relaxation delay
;  delay for binomial water suppression
;d19 ~ 1/(4*offset), offset = excitation max - carrier freq

;N15 Waltz-16 - PCPD2 at pl12
;ds=m*ns, m=1, 2, ..., ns=8, 16, ...

;Recommendations for gradients:
;p15=300u
;p16=450u
;p17=750u
;p18=500

;cnst21= 25G/cm
;cnst22= 25G/cm
;cnst23= 25G/cm
;cnst24= -25G/cm

;comment the following in/out as appropriate
;#define ONE_D
#define N15_EVOL
#define HA_EVOL

;***********************************************
; the following parameters are set automatically
aqseq 321
;
define delay DELTA
define delay DELTA_1
define delay DELTA_2
define delay T
define delay T_1
define delay T_2
define delay ZETA
define delay ZETA_1
define delay ZETA_2
define delay ZETA_3
define delay ZETA_4
define pulse H1_90
define pulse H1_180
define pulse N15_90
define pulse N15_180

"d10=3u"   ;no phase correction in 15N dim.
"d11=100m"
"d12=10u"
"d13=5u"
"d16=300u"
"d28=p2-p1"

"DELTA=5.3m"
"DELTA_1=DELTA-p15-d13"
"DELTA_2=DELTA-p15-d16"
"ZETA=13.4m"
"ZETA_1=ZETA-DELTA-p2-p16"
"ZETA_2=ZETA-p17-d16"
"ZETA_3=ZETA-p17-d13"
"ZETA_4=ZETA-DELTA-p2-p16-d16"
"T=(ZETA*2+H1_180-DELTA-N15_90-N15_180)/2"
"T_1=T-p16-d10-p2*1.5"
"T_2=T-p17-d10-d13-p2*1.5"
"H1_90=p1"
"H1_180=p1*2"
"N15_90=p2"
"N15_180=p2*2"

#include <Avance.incl>
#include <Gradfa.incl>

1 ze
2 d11 do:f2
  d13
3 d13
  d13*2
4 d13
  d13
5 d13
  d13*2
6 20u LOCKH_OFF
  d1 pl1:f1 pl2:f2
;--------------------- Purge 15N before start ---------------
  (N15_90 ph0):f3
  20u LOCKH_ON
  d13
  GRADIENT15(cnst21)   		;300u, 25G/cm
  d16
;------------------- Transfer to 15N and HA --------------------
  (H1_90 ph21):f1
#ifndef HA_EVOL
  d28
#endif
  d13
  GRADIENT15(cnst21)   		;300u, 25G/cm
  DELTA_1 
  (N15_90 ph12):f2
  GRADIENT16(cnst22)   		;450u, 25G/cm
  (ZETA_1 H1_180 ph21 ZETA_2):f1 (T_1 d10 N15_180 ph0):f2 
  GRADIENT17(cnst23)   		;750u, 25G/cm
  d16
#ifndef HA_EVOL
  (d28 H1_90 ph21 H1_90 ph0):f1 (N15_180 ph14):f2 
#else
  (H1_90 ph21):f1
  d0
  (N15_180 ph14):f2
  d0
  (H1_90 ph0):f1
#endif
  d13
  GRADIENT17(cnst23)   		;750u, 25G/cm
  (ZETA_3 H1_180 ph0 ZETA_4):f1 (T_2 d10 N15_180 ph0):f2 
  GRADIENT16(cnst22)   		;450u, 25G/cm
  d16
  (N15_90 ph0):f2
  DELTA_2 
  GRADIENT15(cnst21)   		;300u, 25G/cm
  d16 pl12:f2
#ifndef HA_EVOL
  d28
#endif
  (H1_90 ph0):f1
  d13
  GRADIENT18(cnst24)		;1m, -25G/cm
  1.5m
  (H1_90 ph13):f1
  d19
  (p0 ph23):f1
  go=2 ph31 cpd2:f2
#ifdef ONE_D
  d11 do:f2 wr #0
#else
  d11 do:f2 wr #0 if #0 zd
#endif
#ifdef HA_EVOL
  d13 ip21
  lo to 3 times 2
  d13 id0
  d13 ip31
  d13 ip31
  lo to 4 times l4
  d13 rd0
#endif
#ifdef N15_EVOL
  d13 ip12
  lo to 5 times 2
  d13 id10
  d13 ip31
  d13 ip31
  lo to 6 times l6
#endif
  20u LOCKH_OFF
exit

ph0=0
ph1=1
ph2=2
ph3=3
ph11=0 0 2 2
ph12=0
ph13=0 0 0 0 1 1 1 1
ph14=0 1
ph21=0 0 2 2
ph23=2 2 2 2 3 3 3 3
ph31=0 2 2 0 1 3 3 1

;*** bvhnha.r ***
; put in /u/exp/stan/nmr/lists/gp
; remove semicolons

;p15 { (0) | (0) | (0)+(cnst21) }
;    { (0) | (0) | (0)          }
;p15 { (0) | (0) | (0)+(cnst21) }
;    { (0) | (0) | (0)          }
;p16 { (0) | (0) | (0)+(cnst22) }
;    { (0) | (0) | (0)          }
;p17 { (0) | (0) | (0)+(cnst23) }
;    { (0) | (0) | (0)          }
;p17 { (0) | (0) | (0)+(cnst23) }
;    { (0) | (0) | (0)          }
;p16 { (0) | (0) | (0)+(cnst22) }
;    { (0) | (0) | (0)          }
;p15 { (0) | (0) | (0)+(cnst21) }
;    { (0) | (0) | (0)          }
;p18 { (0)+(cnst24*1.9) | (0) | (0)+(cnst24) }
;    { (0) | (0) | (0)          }